Split TARGET_BASEPATH from breakpad.

TARGET_BASEPATH becomes QMAKE_RESOLVED_TARGET.

QMAKE_RESOLVED_TARGET will be reused for future implementation
of code coverage tool TestCocoon.

Creating of resolve_target.prf.

Clean unused "unset(SYMBOLFILENAME)" in default_post.prf.

Change-Id: I054efb0065fa06697b60ac60a9ddf364f2f40366
Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@nokia.com>

1 files changed, 58 insertions, 0 deletions

diff --git a/mkspecs/features/resolve_target.prf b/mkspecs/features/resolve_target.prf
new file mode 100644
index 0000000000..24d2e0d6b4
--- /dev/null
+++ b/mkspecs/features/resolve_target.prf
@@ -0,0 +1,58 @@
+!contains(DESTDIR, (/|.:[/\\\\]).*):QMAKE_RESOLVED_TARGET = $${OUT_PWD}/
+!isEmpty(DESTDIR):QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${DESTDIR}/
+
+win32 {
+    QMAKE_RESOLVED_TARGET ~= s,/,\\,
+    contains(TEMPLATE, .*lib) {
+        isEmpty(TARGET_VERSION_EXT):!isEmpty(VERSION) {
+            TARGET_VERSION_EXT = $$section(VERSION, ., 0, 0)
+            isEqual(TARGET_VERSION_EXT, 0):unset(TARGET_VERSION_EXT)
+        }
+        TARGET_EXT = .dll
+    } else {
+        TARGET_EXT = .exe
+    }
+    QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${TARGET}$${TARGET_VERSION_EXT}$${TARGET_EXT}
+} else {
+    contains(TEMPLATE, .*lib):LIBPREFIX = lib
+
+    macx {
+        equals(TEMPLATE, lib) {
+            lib_bundle {
+                QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${TARGET}.framework/$${TARGET}
+            } else {
+                QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${LIBPREFIX}$${TARGET}
+                !plugin {
+                    TEMP_VERSION = $$section(VERSION, ., 0, 0)
+                    isEmpty(TEMP_VERSION):TEMP_VERSION = 1
+                    QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}.$${TEMP_VERSION}
+                }
+                QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}.$${QMAKE_EXTENSION_SHLIB}
+            }
+        } else {
+            app_bundle {
+                QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${TARGET}.app/Contents/MacOS/$${TARGET}
+            } else {
+                QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${TARGET}
+            }
+        }
+    } else {
+        equals(TEMPLATE, lib) {
+            plugin {
+                QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${LIBPREFIX}$${TARGET}.so
+            } else {
+                TEMP_VERSION = $$VERSION
+                isEmpty(TEMP_VERSION):TEMP_VERSION = 1.0.0
+                QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${LIBPREFIX}$${TARGET}.so.$${TEMP_VERSION}
+            }
+        } else {
+            QMAKE_RESOLVED_TARGET = $${QMAKE_RESOLVED_TARGET}$${TARGET}
+        }
+    }
+}
+
+unset(TARGET_VERSION_EXT)
+unset(TARGET_EXT)
+unset(LIBPREFIX)
+unset(TEMP_VERSION)
+