mkspecs: Add a win32-clang-g++ mkspec, for clang targeting mingw, like g++

Change-Id: I427e46e6c34c2beeb2a815f1af512e4e8bd213c2
Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@qt.io>

2 files changed, 130 insertions, 0 deletions

diff --git a/mkspecs/win32-clang-g++/qmake.conf b/mkspecs/win32-clang-g++/qmake.conf
new file mode 100644
index 0000000000..1cae64ce99
--- /dev/null
+++ b/mkspecs/win32-clang-g++/qmake.conf
@@ -0,0 +1,90 @@
+#
+# qmake configuration for win32-clang-g++
+#
+# Written for MinGW-w64 / clang 6.0 or higher
+#
+# Cross compile example for x86_64-w64-mingw32-clang++:
+#   configure -xplatform win32-clang-g++ -device-option CROSS_COMPILE=x86_64-w64-mingw32-
+#
+
+load(device_config)
+include(../common/gcc-base.conf)
+include(../common/g++-base.conf)
+include(../common/angle.conf)
+include(../common/windows-vulkan.conf)
+
+# modifications to gcc-base.conf and g++-base.conf
+
+MAKEFILE_GENERATOR      = MINGW
+QMAKE_PLATFORM          = win32 mingw
+CONFIG                 += debug_and_release debug_and_release_target precompile_header
+DEFINES                += UNICODE _UNICODE WIN32
+QMAKE_COMPILER          = gcc clang llvm   # clang pretends to be gcc
+QMAKE_COMPILER_DEFINES += __GNUC__ _WIN32
+# can't add 'DEFINES += WIN64' and 'QMAKE_COMPILER_DEFINES += _WIN64' defines for
+# x86_64 platform similar to 'msvc-desktop.conf' toolchain, because, unlike for MSVC,
+# 'QMAKE_TARGET.arch' is inherently unavailable.
+
+QMAKE_CC                = $${CROSS_COMPILE}clang
+QMAKE_LEX               = flex
+QMAKE_LEXFLAGS          =
+QMAKE_YACC              = bison -y
+QMAKE_YACCFLAGS         = -d
+QMAKE_CFLAGS           +=
+QMAKE_CFLAGS_WARN_ON   += -Wextra -Wno-ignored-attributes
+
+QMAKE_CFLAGS_SSE2      += -mstackrealign
+
+QMAKE_CXX               = $${CROSS_COMPILE}clang++
+QMAKE_CXXFLAGS          = $$QMAKE_CFLAGS
+QMAKE_CXXFLAGS_WARN_ON  = $$QMAKE_CFLAGS_WARN_ON
+QMAKE_CXXFLAGS_RTTI_ON  = -frtti
+QMAKE_CXXFLAGS_RTTI_OFF = -fno-rtti
+QMAKE_CXXFLAGS_EXCEPTIONS_ON = -fexceptions -mthreads
+
+QMAKE_INCDIR            =
+
+QMAKE_RUN_CC            = $(CC) -c $(CFLAGS) $(INCPATH) -o $obj $src
+QMAKE_RUN_CC_IMP        = $(CC) -c $(CFLAGS) $(INCPATH) -o $@ $<
+QMAKE_RUN_CXX           = $(CXX) -c $(CXXFLAGS) $(INCPATH) -o $obj $src
+QMAKE_RUN_CXX_IMP       = $(CXX) -c $(CXXFLAGS) $(INCPATH) -o $@ $<
+
+QMAKE_LINK              = $${CROSS_COMPILE}clang++
+QMAKE_LINK_C            = $${CROSS_COMPILE}clang
+QMAKE_LFLAGS_EXCEPTIONS_ON = -mthreads
+QMAKE_LFLAGS_RELEASE    = -Wl,-s
+QMAKE_LFLAGS_CONSOLE    = -Wl,-subsystem,console
+QMAKE_LFLAGS_WINDOWS    = -Wl,-subsystem,windows
+QMAKE_LFLAGS_DLL        = -shared
+QMAKE_LFLAGS_GCSECTIONS = -Wl,--gc-sections
+equals(QMAKE_HOST.os, Windows) {
+    QMAKE_LINK_OBJECT_MAX = 10
+    QMAKE_LINK_OBJECT_SCRIPT = object_script
+}
+QMAKE_EXT_OBJ           = .o
+QMAKE_EXT_RES           = _res.o
+QMAKE_PREFIX_SHLIB      =
+QMAKE_EXTENSION_SHLIB   = dll
+QMAKE_PREFIX_STATICLIB  = lib
+QMAKE_EXTENSION_STATICLIB = a
+QMAKE_LIB_EXTENSIONS    = a dll.a
+
+QMAKE_LIBS              =
+QMAKE_LIBS_GUI          = -lgdi32 -lcomdlg32 -loleaut32 -limm32 -lwinmm -lws2_32 -lole32 -luuid -luser32 -ladvapi32
+QMAKE_LIBS_NETWORK      = -lws2_32
+QMAKE_LIBS_OPENGL       = -lglu32 -lopengl32 -lgdi32 -luser32
+QMAKE_LIBS_OPENGL_ES2   = -lgdi32 -luser32
+QMAKE_LIBS_OPENGL_ES2_DEBUG = -lgdi32 -luser32
+QMAKE_LIBS_COMPAT       = -ladvapi32 -lshell32 -lcomdlg32 -luser32 -lgdi32 -lws2_32
+QMAKE_LIBS_QT_ENTRY     = -lmingw32 -lqtmain
+
+QMAKE_IDL               = midl
+QMAKE_LIB               = $${CROSS_COMPILE}ar -rc
+QMAKE_RC                = $${CROSS_COMPILE}windres
+
+QMAKE_STRIP             = $${CROSS_COMPILE}strip
+QMAKE_STRIPFLAGS_LIB   += --strip-unneeded
+QMAKE_OBJCOPY           = $${CROSS_COMPILE}objcopy
+QMAKE_NM                = $${CROSS_COMPILE}nm -P
+
+load(qt_config)
diff --git a/mkspecs/win32-clang-g++/qplatformdefs.h b/mkspecs/win32-clang-g++/qplatformdefs.h
new file mode 100644
index 0000000000..906e724c19
--- /dev/null
+++ b/mkspecs/win32-clang-g++/qplatformdefs.h
@@ -0,0 +1,40 @@
+/****************************************************************************
+**
+** Copyright (C) 2018 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the qmake spec of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl-3.0.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or (at your option) the GNU General
+** Public license version 3 or any later version approved by the KDE Free
+** Qt Foundation. The licenses are as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL2 and LICENSE.GPL3
+** included in the packaging of this file. Please review the following
+** information to ensure the GNU General Public License requirements will
+** be met: https://www.gnu.org/licenses/gpl-2.0.html and
+** https://www.gnu.org/licenses/gpl-3.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+#include "../win32-g++/qplatformdefs.h"