Add gradle wrapper to Qt & update default Andriod gradle plugin

We need to add gradle wrapper to Qt because it was removed from latest Android SDK.
Adding it to Qt, will give us more control and will save us from pain in the future.

Task-number: QTBUG-59237
Change-Id: I6419876f8be11c0feeac448b228a46f811065264
Reviewed-by: Eskil Abrahamsen Blomfeldt <eskil.abrahamsen-blomfeldt@qt.io>

1 files changed, 23 insertions, 0 deletions

diff --git a/src/3rdparty/gradle/gradle.pro b/src/3rdparty/gradle/gradle.pro
new file mode 100644
index 0000000000..bad41e3468
--- /dev/null
+++ b/src/3rdparty/gradle/gradle.pro
@@ -0,0 +1,23 @@
+CONFIG -= qt android_install
+
+gradle.files = \
+    $$PWD/gradlew \
+    $$PWD/gradlew.bat \
+    $$PWD/gradle
+
+gradle.path = $$[QT_INSTALL_PREFIX]/src/3rdparty/gradle
+
+INSTALLS += gradle
+
+!prefix_build:!equals(OUT_PWD, $$PWD) {
+    RETURN = $$escape_expand(\\n\\t)
+    equals(QMAKE_HOST.os, Windows) {
+        RETURN = $$escape_expand(\\r\\n\\t)
+    }
+    OUT_PATH = $$shell_path($$OUT_PWD)
+
+    QMAKE_POST_LINK += \
+        $${QMAKE_COPY} $$shell_path($$PWD/gradlew) $$OUT_PATH $$RETURN \
+        $${QMAKE_COPY} $$shell_path($$PWD/gradlew.bat) $$OUT_PATH $$RETURN \
+        $${QMAKE_COPY_DIR} $$shell_path($$PWD/gradle) $$OUT_PATH
+}