Add V8 snapshot support

A V8 snapshot is a serialized representation of the JavaScript heap.
Using a snapshot can vastly speed up V8 initialization.

This commit introduces a new tool, mkv8snapshot. mkv8snapshot is
automatically invoked as part of building QtV8, and generates a .cpp
file which is compiled into the QtV8 library.

Because mkv8snapshot itself needs to initialize the V8 environment
the non-snapshot way (i.e., by evaluating thousands of lines of
JavaScript), it needs to build all of V8. This means that V8 is
effectively built twice when snapshots are enabled.

When cross-compiling, only host=i386 and target=arm is supported,
since that's the only relevant case for which V8 currently
supports a simulator. mkv8snapshot is built and run as a host tool
(using the simulator), and generates a snapshot that will be used
on the target.

Task-number: QTBUG-21152
Change-Id: I9270652f129505508f78db8b0a39fbf57dc8b86d
Reviewed-by: Friedemann Kleint <Friedemann.Kleint@nokia.com>
Reviewed-by: Lars Knoll <lars.knoll@nokia.com>

2 files changed, 33 insertions, 23 deletions

diff --git a/src/v8/v8.pri b/src/v8/v8.pri
index 868bbad207..26feca9b34 100644
--- a/src/v8/v8.pri
+++ b/src/v8/v8.pri
@@ -5,16 +5,19 @@ isEmpty(QT_ARCH) {
     load(qt_config)
 }
 
-equals(QT_ARCH, x86_64)|contains(CONFIG, x86_64):CONFIG += arch_x86_64
-else:equals(QT_ARCH, "i386"):CONFIG += arch_i386
-else:equals(QT_ARCH, "arm"):CONFIG += arch_arm
-else:equals(QMAKE_HOST.arch, armv7l):CONFIG += arch_arm
-else:equals(QMAKE_HOST.arch, armv5tel):CONFIG += arch_arm
-else:equals(QMAKE_HOST.arch, x86_64):CONFIG += arch_x86_64
-else:equals(QMAKE_HOST.arch, x86):CONFIG += arch_i386
-else:equals(QMAKE_HOST.arch, i386):CONFIG += arch_i386
-else:equals(QMAKE_HOST.arch, i686):CONFIG += arch_i386
-else:error("Couldn't detect supported architecture ($$QMAKE_HOST.arch/$$QT_ARCH). Currently supported architectures are: x64, x86 and arm")
+isEmpty(V8_TARGET_ARCH) {
+    # Detect target
+    equals(QT_ARCH, x86_64)|contains(CONFIG, x86_64):V8_TARGET_ARCH = x64
+    else:equals(QT_ARCH, "i386"):                    V8_TARGET_ARCH = ia32
+    else:equals(QT_ARCH, "arm"):                     V8_TARGET_ARCH = arm
+    else:equals(QMAKE_HOST.arch, armv7l):            V8_TARGET_ARCH = arm
+    else:equals(QMAKE_HOST.arch, armv5tel):          V8_TARGET_ARCH = arm
+    else:equals(QMAKE_HOST.arch, x86_64):            V8_TARGET_ARCH = x64
+    else:equals(QMAKE_HOST.arch, x86):               V8_TARGET_ARCH = ia32
+    else:equals(QMAKE_HOST.arch, i386):              V8_TARGET_ARCH = ia32
+    else:equals(QMAKE_HOST.arch, i686):              V8_TARGET_ARCH = ia32
+    else:error("Couldn't detect supported v8 architecture ($$QMAKE_HOST.arch/$$QT_ARCH). Currently supported architectures are: x64, x86 and arm")
+}
 
 include($$PWD/v8base.pri)
 
@@ -23,8 +26,6 @@ include($$PWD/v8base.pri)
 CONFIG(debug, debug|release):V8_GENERATED_SOURCES_DIR = generated-debug
 else:                        V8_GENERATED_SOURCES_DIR = generated-release
 
-!contains(QT_CONFIG, static): DEFINES += V8_SHARED BUILDING_V8_SHARED
-
 # this maybe removed in future
 DEFINES += ENABLE_DEBUGGER_SUPPORT
 
@@ -145,10 +146,7 @@ SOURCES += \
     $$V8SRC/extensions/gc-extension.cc \
     $$V8SRC/extensions/externalize-string-extension.cc
 
-SOURCES += \
-    $$V8SRC/snapshot-empty.cc \
-
-arch_arm {
+equals(V8_TARGET_ARCH, arm) {
 DEFINES += V8_TARGET_ARCH_ARM
 SOURCES += \
     $$V8SRC/arm/builtins-arm.cc \
@@ -169,9 +167,7 @@ SOURCES += \
     $$V8SRC/arm/regexp-macro-assembler-arm.cc \
     $$V8SRC/arm/stub-cache-arm.cc \
     $$V8SRC/arm/assembler-arm.cc
-}
-
-arch_i386 {
+} else:equals(V8_TARGET_ARCH, ia32) {
 DEFINES += V8_TARGET_ARCH_IA32
 SOURCES += \
     $$V8SRC/ia32/assembler-ia32.cc \
@@ -191,10 +187,8 @@ SOURCES += \
     $$V8SRC/ia32/macro-assembler-ia32.cc \
     $$V8SRC/ia32/regexp-macro-assembler-ia32.cc \
     $$V8SRC/ia32/stub-cache-ia32.cc
-}
-
-# FIXME Should we use QT_CONFIG instead? What about 32 bit Macs?
-arch_x86_64 {
+} else:equals(V8_TARGET_ARCH, x64) {
+# FIXME What about 32-bit Macs?
 DEFINES += V8_TARGET_ARCH_X64
 SOURCES += \
     $$V8SRC/x64/assembler-x64.cc \
diff --git a/src/v8/v8.pro b/src/v8/v8.pro
index ae43f244cf..1bc542ee32 100644
--- a/src/v8/v8.pro
+++ b/src/v8/v8.pro
@@ -22,4 +22,20 @@ INCLUDEPATH -= $$MODULE_INCLUDES $$MODULE_INCLUDES/..
 
 HEADERS += $$QT_SOURCE_TREE/src/v8/qtv8version.h
 
+!contains(QT_CONFIG, static): DEFINES += V8_SHARED BUILDING_V8_SHARED
+
 include(v8.pri)
+
+contains(QT_CONFIG, v8snapshot) {
+    mkv8snapshot.commands = ../../bin/mkv8snapshot ${QMAKE_FILE_OUT}
+    DUMMY_FILE = v8.pro
+    mkv8snapshot.input = DUMMY_FILE
+    mkv8snapshot.output = $$V8_GENERATED_SOURCES_DIR/snapshot.cpp
+    mkv8snapshot.variable_out = SOURCES
+    mkv8snapshot.dependency_type = TYPE_C
+    mkv8snapshot.name = generating[v8] ${QMAKE_FILE_IN}
+    silent:mkv8snapshot.commands = @echo generating[v8] ${QMAKE_FILE_IN} && $$mkv8snapshot.commands
+    QMAKE_EXTRA_COMPILERS += mkv8snapshot
+} else {
+    SOURCES += $$V8SRC/snapshot-empty.cc
+}