Remove the qmake project files

Remove the qmake project files for most of Qt.

Leave the qmake project files for examples, because we still test those
in the CI to ensure qmake does not regress.

Also leave the qmake project files for utils and other minor parts that
lack CMake project files.

Task-number: QTBUG-88742
Change-Id: I6cdf059e6204816f617f9624f3ea9822703f73cc
Reviewed-by: Edward Welbourne <edward.welbourne@qt.io>
Reviewed-by: Qt CI Bot <qt_ci_bot@qt-project.org>
Reviewed-by: Kai Koehne <kai.koehne@qt.io>

12 files changed, 0 insertions, 176 deletions

diff --git a/tests/auto/corelib/plugin/qpluginloader/almostplugin/almostplugin.pro b/tests/auto/corelib/plugin/qpluginloader/almostplugin/almostplugin.pro
deleted file mode 100644
index abfc70883e..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/almostplugin/almostplugin.pro
+++ /dev/null
@@ -1,12 +0,0 @@
-TEMPLATE      = lib
-CONFIG       += plugin
-HEADERS       = almostplugin.h
-SOURCES       = almostplugin.cpp
-TARGET        = almostplugin
-DESTDIR       = ../bin
-QT = core
-*-g++*:QMAKE_LFLAGS -= -Wl,--no-undefined
-
-# This is testdata for the tst_qpluginloader test.
-target.path = $$[QT_INSTALL_TESTS]/tst_qpluginloader/bin
-INSTALLS += target
diff --git a/tests/auto/corelib/plugin/qpluginloader/lib/lib.pro b/tests/auto/corelib/plugin/qpluginloader/lib/lib.pro
deleted file mode 100644
index aa72a80559..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/lib/lib.pro
+++ /dev/null
@@ -1,13 +0,0 @@
-TEMPLATE = lib
-CONFIG += dll
-CONFIG -= staticlib
-SOURCES		= mylib.c
-TARGET = tst_qpluginloaderlib
-DESTDIR = ../bin
-QT = core
-
-msvc: DEFINES += WIN32_MSVC
-
-# This is testdata for the tst_qpluginloader test.
-target.path = $$[QT_INSTALL_TESTS]/tst_qpluginloader/bin
-INSTALLS += target
diff --git a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest.pri b/tests/auto/corelib/plugin/qpluginloader/machtest/machtest.pri
deleted file mode 100644
index ca4a0a07e9..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest.pri
+++ /dev/null
@@ -1,13 +0,0 @@
-TEMPLATE = aux
-
-# Needs explicit load()ing due to aux template. Relies on QT being non-empty.
-load(qt)
-
-goodlib.target = good.$${QMAKE_APPLE_DEVICE_ARCHS}.dylib
-goodlib.commands = $(CXX) $(CXXFLAGS) -shared -o $@ -I$(INCPATH) $<
-goodlib.depends += $$PWD/../fakeplugin.cpp
-
-all.depends += goodlib
-
-QMAKE_EXTRA_TARGETS += goodlib all
-QMAKE_CLEAN += $$goodlib.target
diff --git a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest.pro b/tests/auto/corelib/plugin/qpluginloader/machtest/machtest.pro
deleted file mode 100644
index 795dd89895..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest.pro
+++ /dev/null
@@ -1,15 +0,0 @@
-TEMPLATE = subdirs
-
-SUBDIRS = \
-    machtest_i386.pro \
-    machtest_x86_64.pro \
-    machtest_ppc64.pro \
-    machtest_fat.pro
-
-machtest_fat-pro.depends = \
-    machtest_i386.pro \
-    machtest_x86_64.pro \
-    machtest_ppc64.pro
-
-machtest_ppc64-pro.depends = \
-    machtest_x86_64.pro
diff --git a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_fat.pro b/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_fat.pro
deleted file mode 100644
index 9c34a873bc..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_fat.pro
+++ /dev/null
@@ -1,47 +0,0 @@
-TEMPLATE = aux
-OTHER_FILES += generate-bad.pl
-
-# Needs explicit load()ing due to aux template. Relies on QT being non-empty.
-load(qt)
-
-# Generate a fat binary with three architectures
-fat_all.target = good.fat.all.dylib
-fat_all.commands = lipo -create -output $@ \
-                              -arch ppc64 good.ppc64.dylib \
-                              -arch i386 good.i386.dylib \
-                              -arch x86_64 good.x86_64.dylib
-fat_all.depends += good.i386.dylib good.x86_64.dylib good.ppc64.dylib
-
-fat_no_i386.target = good.fat.no-i386.dylib
-fat_no_i386.commands = lipo -create -output $@ -arch x86_64 good.x86_64.dylib -arch ppc64 good.ppc64.dylib
-fat_no_i386.depends += good.x86_64.dylib good.ppc64.dylib
-
-fat_no_x86_64.target = good.fat.no-x86_64.dylib
-fat_no_x86_64.commands = lipo -create -output $@ -arch i386 good.i386.dylib -arch ppc64 good.ppc64.dylib
-fat_no_x86_64.depends += good.i386.dylib good.ppc64.dylib
-
-stub_i386.commands = $$QMAKE_CXX -shared -arch i386 -o stub.i386.dylib $$PWD/stub.cpp
-stub_i386.depends += $$PWD/stub.cpp
-
-stub_x86_64.commands = $$QMAKE_CXX -shared -arch x86_64 -o stub.x86_64.dylib $$PWD/stub.cpp
-stub_x86_64.depends += $$PWD/stub.cpp
-
-fat_stub_i386.target = good.fat.stub-i386.dylib
-fat_stub_i386.commands = lipo -create -output $@ -arch ppc64 good.ppc64.dylib -arch i386 stub.i386.dylib
-fat_stub_i386.depends += stub_i386 good.x86_64.dylib good.ppc64.dylib
-
-fat_stub_x86_64.target = good.fat.stub-x86_64.dylib
-fat_stub_x86_64.commands = lipo -create -output $@ -arch ppc64 good.ppc64.dylib -arch x86_64 stub.x86_64.dylib
-fat_stub_x86_64.depends += stub_x86_64 good.i386.dylib good.ppc64.dylib
-
-bad.commands = $$PWD/generate-bad.pl
-bad.depends += $$PWD/generate-bad.pl
-
-MYTARGETS = $$fat_all.depends fat_all fat_no_x86_64 fat_no_i386 \
-            fat_stub_i386 fat_stub_x86_64 bad stub_i386 stub_x86_64
-all.depends += $$MYTARGETS
-QMAKE_EXTRA_TARGETS += $$MYTARGETS all
-
-QMAKE_CLEAN += $$fat_all.target $$fat_no_i386.target $$fat_no_x86_64.target \
-            $$fat_stub_i386.target $$fat_stub_x86_64.target \
-            "bad*.dylib"
diff --git a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_i386.pro b/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_i386.pro
deleted file mode 100644
index bfb2e0930c..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_i386.pro
+++ /dev/null
@@ -1,3 +0,0 @@
-QMAKE_APPLE_DEVICE_ARCHS = i386
-include(machtest.pri)
-
diff --git a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_ppc64.pro b/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_ppc64.pro
deleted file mode 100644
index a73f97ccc6..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_ppc64.pro
+++ /dev/null
@@ -1,9 +0,0 @@
-QMAKE_APPLE_DEVICE_ARCHS = ppc64
-include(machtest.pri)
-
-OTHER_FILES += ppcconverter.pl
-
-# Current macOS toolchains have no compiler for PPC anymore
-# So we fake it by converting an x86-64 binary to (little-endian!) PPC64
-goodlib.commands = $$PWD/ppcconverter.pl $< $@
-goodlib.depends = good.x86_64.dylib $$PWD/ppcconverter.pl
diff --git a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_x86_64.pro b/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_x86_64.pro
deleted file mode 100644
index 9dbae5c4ee..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/machtest/machtest_x86_64.pro
+++ /dev/null
@@ -1,2 +0,0 @@
-QMAKE_APPLE_DEVICE_ARCHS = x86_64
-include(machtest.pri)
diff --git a/tests/auto/corelib/plugin/qpluginloader/qpluginloader.pro b/tests/auto/corelib/plugin/qpluginloader/qpluginloader.pro
deleted file mode 100644
index 18c9c8d198..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/qpluginloader.pro
+++ /dev/null
@@ -1,21 +0,0 @@
-QT = core
-TEMPLATE = subdirs
-
-tst.depends = lib theplugin
-SUBDIRS = lib \
-          staticplugin \
-          theplugin \
-          tst
-!android:!win32:!darwin {
-    tst.depends += almostplugin
-    SUBDIRS += almostplugin
-}
-macos:qtConfig(private_tests):qtHaveModule(gui) {
-    tst.depends += machtest
-    SUBDIRS += machtest
-}
-
-# no special install rule for subdir
-INSTALLS =
-
-
diff --git a/tests/auto/corelib/plugin/qpluginloader/staticplugin/staticplugin.pro b/tests/auto/corelib/plugin/qpluginloader/staticplugin/staticplugin.pro
deleted file mode 100644
index ff65ab728c..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/staticplugin/staticplugin.pro
+++ /dev/null
@@ -1,7 +0,0 @@
-TEMPLATE = lib
-CONFIG += plugin static
-SOURCES = main.cpp
-QT = core
-
-# Add extra metadata to the plugin
-QMAKE_MOC_OPTIONS += -M ExtraMetaData=StaticPlugin -M ExtraMetaData=foo
diff --git a/tests/auto/corelib/plugin/qpluginloader/theplugin/theplugin.pro b/tests/auto/corelib/plugin/qpluginloader/theplugin/theplugin.pro
deleted file mode 100644
index 6ec4a8de05..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/theplugin/theplugin.pro
+++ /dev/null
@@ -1,13 +0,0 @@
-TEMPLATE      = lib
-CONFIG       += plugin
-HEADERS       = theplugin.h
-SOURCES       = theplugin.cpp
-# Use a predictable name for the plugin, no debug extension. Just like most apps do.
-#TARGET        = $$qtLibraryTarget(theplugin)
-TARGET        = theplugin
-DESTDIR       = ../bin
-QT = core
-
-# This is testdata for the tst_qpluginloader test.
-target.path = $$[QT_INSTALL_TESTS]/tst_qpluginloader/bin
-INSTALLS += target
diff --git a/tests/auto/corelib/plugin/qpluginloader/tst/tst.pro b/tests/auto/corelib/plugin/qpluginloader/tst/tst.pro
deleted file mode 100644
index d49bff14fd..0000000000
--- a/tests/auto/corelib/plugin/qpluginloader/tst/tst.pro
+++ /dev/null
@@ -1,21 +0,0 @@
-CONFIG += testcase
-TARGET  = ../tst_qpluginloader
-QT = core testlib
-qtConfig(private_tests): QT += core-private
-SOURCES = ../tst_qpluginloader.cpp ../fakeplugin.cpp
-HEADERS = ../theplugin/plugininterface.h
-
-win32:debug_and_release {
-    CONFIG(debug, debug|release) {
-        TARGET = ../../debug/tst_qpluginloader
-        LIBS += -L../staticplugin/debug
-    } else {
-        TARGET = ../../release/tst_qpluginloader
-        LIBS += -L../staticplugin/release
-    }
-} else {
-    LIBS += -L../staticplugin
-}
-LIBS += -lstaticplugin
-
-TESTDATA += ../elftest ../machtest