Moved network autotests into new directory structure

Task-number: QTBUG-21223

Change-Id: I55dbf5c42a1c5d938b9e0c9bf7d90457a6c26bbc
Reviewed-on: http://codereview.qt-project.org/4259
Reviewed-by: Qt Sanity Bot <qt_sanity_bot@ovi.com>
Reviewed-by: Sergio Ahumada <sergio.ahumada@nokia.com>
Reviewed-by: Rohan McGovern <rohan.mcgovern@nokia.com>

1 files changed, 50 insertions, 0 deletions

diff --git a/tests/auto/network/socket/qlocalsocket/test/test.pro b/tests/auto/network/socket/qlocalsocket/test/test.pro
new file mode 100644
index 0000000000..b2755b5411
--- /dev/null
+++ b/tests/auto/network/socket/qlocalsocket/test/test.pro
@@ -0,0 +1,50 @@
+load(qttest_p4)
+
+DEFINES += QLOCALSERVER_DEBUG
+DEFINES += QLOCALSOCKET_DEBUG
+
+symbian {
+    # nothing
+} else:wince* {
+    DEFINES += QT_LOCALSOCKET_TCP
+    DEFINES += SRCDIR=\\\"../\\\"
+} else {
+    DEFINES += SRCDIR=\\\"$$PWD/../\\\"
+}
+
+QT = core network
+
+SOURCES += ../tst_qlocalsocket.cpp
+
+TARGET = tst_qlocalsocket
+CONFIG(debug_and_release) {
+  CONFIG(debug, debug|release) {
+    DESTDIR = ../debug
+  } else {
+    DESTDIR = ../release
+  }
+} else {
+  DESTDIR = ..
+}
+
+wince* {
+    additionalFiles.files = ../lackey/lackey.exe
+    additionalFiles.path = lackey
+}
+
+symbian {
+    additionalFiles.files = lackey.exe
+    additionalFiles.path = \\sys\\bin
+    TARGET.UID3 = 0xE0340005
+    DEFINES += SYMBIAN_SRCDIR_UID=$$lower($$replace(TARGET.UID3,"0x",""))
+}
+
+wince*|symbian {
+    scriptFiles.files = ../lackey/scripts/*.js
+    scriptFiles.path = lackey/scripts
+    DEPLOYMENT += additionalFiles scriptFiles
+    QT += script    # for easy deployment of QtScript
+    
+    requires(contains(QT_CONFIG,script))
+}
+