1 files changed, 63 insertions, 0 deletions
diff --git a/mkspecs/devices/linux-archos-gen8-g++/qmake.conf b/mkspecs/devices/linux-archos-gen8-g++/qmake.conf
new file mode 100644
index 0000000000..5e1fe8aea7
--- /dev/null
+++ b/mkspecs/devices/linux-archos-gen8-g++/qmake.conf
@@ -0,0 +1,63 @@
+#
+# qmake configuration for the Archos gen8 tablets (70 and 101)
+# with the SDE (Software Developer Edition) firmware
+# http://www.archos.com/support/support_tech/updates_dev.html
+#
+# OpenEmbedded platform build system for Qt5 available at:
+# http://github.com/KDAB/OpenEmbedded-Archos
+
+MAKEFILE_GENERATOR      = UNIX
+TARGET_PLATFORM         = unix
+TEMPLATE                = app
+CONFIG                  += qt warn_on release incremental link_prl gdb_dwarf_index
+QT                      += core gui
+QMAKE_INCREMENTAL_STYLE = sublib
+
+include(../../common/linux.conf)
+include(../../common/gcc-base-unix.conf)
+include(../../common/g++-unix.conf)
+
+load(device_config)
+
+QT_QPA_DEFAULT_PLATFORM = eglfs
+
+isEmpty(CROSS_COMPILE) {
+    CROSS_COMPILE       = arm-angstrom-linux-gnueabi-
+}
+
+# modifications to g++.conf
+QMAKE_CC                = $${CROSS_COMPILE}gcc
+QMAKE_CXX               = $${CROSS_COMPILE}g++
+QMAKE_LINK              = $${QMAKE_CXX}
+QMAKE_LINK_SHLIB        = $${QMAKE_CXX}
+
+# modifications to linux.conf
+QMAKE_AR                = $${CROSS_COMPILE}ar cqs
+QMAKE_OBJCOPY           = $${CROSS_COMPILE}objcopy
+QMAKE_STRIP             = $${CROSS_COMPILE}strip
+
+COMPILER_FLAGS          = -march=armv7-a -mtune=cortex-a8 -mfpu=neon -mfloat-abi=softfp
+
+#modifications to gcc-base.conf
+QMAKE_CFLAGS           += $${COMPILER_FLAGS}
+QMAKE_CXXFLAGS         += $${COMPILER_FLAGS}
+QMAKE_CXXFLAGS_RELEASE += -O3
+
+QMAKE_LIBS             += -lrt -lpthread -ldl
+
+# Extra stuff (OpenGL, DirectFB, ...)
+QMAKE_INCDIR_EGL        = $$[QT_SYSROOT]/usr/include
+QMAKE_LIBDIR_EGL        = $$[QT_SYSROOT]/usr/lib
+QMAKE_INCDIR_OPENGL_ES2 = $${QMAKE_INCDIR_EGL}
+QMAKE_LIBDIR_OPENGL_ES2 = $${QMAKE_LIBDIR_EGL}
+QMAKE_INCDIR_OPENVG     = $${QMAKE_INCDIR_EGL}
+QMAKE_LIBDIR_OPENVG     = $${QMAKE_LIBDIR_EGL}
+
+QMAKE_LIBS_EGL          = -lEGL -lIMGegl -lsrv_um
+QMAKE_LIBS_OPENGL_ES2   = -lGLESv2 $${QMAKE_LIBS_EGL}
+QMAKE_LIBS_OPENVG       = -lOpenVG $${QMAKE_LIBS_EGL}
+
+# Sanity check
+deviceSanityCheckCompiler()
+
+load(qt_config)