1 files changed, 65 insertions, 0 deletions
diff --git a/mkspecs/devices/linux-mipsel-broadcom-97425-g++/qmake.conf b/mkspecs/devices/linux-mipsel-broadcom-97425-g++/qmake.conf
new file mode 100644
index 0000000000..866fad639b
--- /dev/null
+++ b/mkspecs/devices/linux-mipsel-broadcom-97425-g++/qmake.conf
@@ -0,0 +1,65 @@
+#
+# qmake configuration for linux-mipsel-broadcom-97425-g++
+#
+
+MAKEFILE_GENERATOR      = UNIX
+TARGET_PLATFORM         = unix
+TEMPLATE                = app
+CONFIG                  += qt warn_on release incremental link_prl gdb_dwarf_index
+QT                      += core gui
+QMAKE_INCREMENTAL_STYLE = sublib
+
+include(../../common/linux.conf)
+include(../../common/gcc-base-unix.conf)
+include(../../common/g++-unix.conf)
+
+load(device_config)
+
+# Modify the defaults we loaded above
+CROSS_COMPILE           = mipsel-linux-
+QMAKE_CC                = $${CROSS_COMPILE}gcc
+QMAKE_CXX               = $${CROSS_COMPILE}g++
+QMAKE_LINK              = $${QMAKE_CXX}
+QMAKE_LINK_SHLIB        = $${QMAKE_CXX}
+
+QMAKE_AR                = $${CROSS_COMPILE}ar cqs
+QMAKE_OBJCOPY           = $${CROSS_COMPILE}objcopy
+QMAKE_STRIP             = $${CROSS_COMPILE}strip
+
+QMAKE_CFLAGS_RELEASE    += -O2
+QMAKE_CXXFLAGS_RELEASE  += $$QMAKE_CFLAGS_RELEASE
+
+#TODO: Clean Qt to work with uclibc not calling itself GLIBC.
+#QMAKE_CFLAGS           += -D__FORCE_NOGLIBC
+#QMAKE_CXXFLAGS         += -D__FORCE_NOGLIBC
+
+
+BRCM_PLATFORM           = 97425
+
+# Sanity checks
+deviceSanityCheckCompiler()
+isEmpty(B_REFSW_DEBUG):error("B_REFSW_DEBUG needs to be set via -device-option B_REFSW_DEBUG=(y|n).")
+isEmpty(BRCM_ROCKFORD_PATH):error("BRCM_ROCKFORD_PATH needs to be set via -device-option BRCM_ROCKFORD_PATH=path.")
+isEmpty(BRCM_APPLIBS_PATH):error("BRCM_APPLIBS_PATH needs to be set via -device-option BRCM_APPLIBS_PATH=path.")
+
+# Figure the kind of directfb build used.
+BRCM_BUILD_TYPE         = debug
+contains(B_REFSW_DEBUG, [Nn]) {
+    BRCM_BUILD_TYPE     = release
+}
+
+QMAKE_INCDIR_OPENGL_ES2 = $${BRCM_ROCKFORD_PATH}/middleware/v3d/interface/khronos/include
+QMAKE_LIBDIR_OPENGL_ES2 = $${BRCM_ROCKFORD_PATH}/middleware/v3d/lib_$${BRCM_PLATFORM}_$${BRCM_BUILD_TYPE}
+QMAKE_LIBS_OPENGL_ES2   = -lv3ddriver -lrt
+
+INCLUDEPATH             += $${BRCM_APPLIBS_PATH}/opensource/zlib/zlib-1.2.3
+QMAKE_LIBDIR            += $${BRCM_APPLIBS_PATH}/opensource/zlib/zlib-1.2.3
+
+# DirectFB, needs to be changed once -directfb is added to configure
+DIRECTFB_INCLUDEPATH    = $${BRCM_APPLIBS_PATH}/opensource/directfb/bin/DirectFB-1.4.15_multi_$${BRCM_BUILD_TYPE}_build.97425B1/usr/local/include/directfb $${BRCM_ROCKFORD_PATH}/middleware/platform/directfb
+DIRECTFB_LIBS           = -L$${BRCM_APPLIBS_PATH}/opensource/directfb/bin/DirectFB-1.4.15_multi_$${BRCM_BUILD_TYPE}_build.97425B1/usr/local/lib -L$${BRCM_ROCKFORD_PATH}/middleware/platform/directfb/lib_$${BRCM_PLATFORM}_$${BRCM_BUILD_TYPE} -ldirectfb -lfusion -ldirect -lpthread -lnexus -ldbpl -lz
+
+
+QMAKE_LFLAGS            += -Wl,-rpath-link,$$QMAKE_LIBDIR_OPENGL_ES2  -Wl,-rpath-link,$${BRCM_APPLIBS_PATH}/opensource/zlib/zlib-1.2.3
+
+load(qt_config)