1 files changed, 46 insertions, 1 deletions
diff --git a/mkspecs/features/qt_helper_lib.prf b/mkspecs/features/qt_helper_lib.prf
index bc20251bd9..2d67a30fb7 100644
--- a/mkspecs/features/qt_helper_lib.prf
+++ b/mkspecs/features/qt_helper_lib.prf
@@ -89,4 +89,49 @@ TARGET = $$THE_TARGET
 
 # In static builds of Qt, convenience libraries must be installed,
 # as in this case they are not linked to the final library/plugin.
-installed|if(!not_installed:qtConfig(static)): load(qt_installs)
+installed|if(!not_installed:qtConfig(static)) {
+    !isEmpty(MODULE_EXT_HEADERS) {
+        headers.files = $${MODULE_EXT_HEADERS}
+        headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
+        INSTALLS += headers
+    } else {
+        !isEmpty(MODULE_EXT_HEADERS_DIR) {
+            headers.files = $$MODULE_EXT_HEADERS_DIR/*
+            headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
+            INSTALLS += headers
+        }
+    }
+
+    CONFIG += qt_install_module
+    rpl_header_base = $$MODULE_INCLUDEPATH
+    rpl_lib_base = $${MODULE_LIBS}
+    qqt_dir = \$\$\$\$[QT_INSTALL_HEADERS]
+    pri_header_replace.match = $$rpl_header_base
+    pri_header_replace.replace = $$qqt_dir/$$TARGET
+    pri_header_replace.CONFIG = path
+    pri_header_replace.filename = qt_ext_$${MODULE}.pri
+    qqt_dir = \$\$\$\$[QT_INSTALL_LIBS]
+    pri_lib_replace.match = $$rpl_lib_base
+    pri_lib_replace.replace = $$qqt_dir/$$prefix$${THE_TARGET}.$$suffix
+    pri_lib_replace.CONFIG = path
+    pri_lib_replace.filename = qt_ext_$${MODULE}.pri
+    QMAKE_INSTALL_REPLACE += pri_header_replace pri_lib_replace
+    if(msvc|qtConfig(debug_and_release)): {
+        rpl_lib_target = $$prefix$${TARGET}.$$suffix
+        pri_lib_release_replace.match = $$DESTDIR/$${rpl_lib_target}
+        pri_lib_release_replace.replace = $$qqt_dir/$${rpl_lib_target}
+        pri_lib_release_replace.CONFIG = path
+        pri_lib_release_replace.filename = qt_ext_$${MODULE}.pri
+        QMAKE_INSTALL_REPLACE += pri_lib_release_replace
+        win32: \
+            rpl_lib_target = $$prefix$${TARGET}d.$$suffix
+        else: darwin: \
+            rpl_lib_target = $$prefix$${TARGET}_debug.$$suffix
+        pri_lib_debug_replace.match = $$DESTDIR/$${rpl_lib_target}
+        pri_lib_debug_replace.replace = $$qqt_dir/$${rpl_lib_target}
+        pri_lib_debug_replace.CONFIG = path
+        pri_lib_debug_replace.filename = qt_ext_$${MODULE}.pri
+        QMAKE_INSTALL_REPLACE += pri_lib_debug_replace
+    }
+    load(qt_installs)
+}