3 files changed, 0 insertions, 187 deletions
diff --git a/src/plugins/platforms/windows/uiautomation/uiautomation.pri b/src/plugins/platforms/windows/uiautomation/uiautomation.pri
deleted file mode 100644
index fd3ed1c6df..0000000000
--- a/src/plugins/platforms/windows/uiautomation/uiautomation.pri
+++ /dev/null
@@ -1,43 +0,0 @@
-SOURCES += \
-    $$PWD/qwindowsuiaaccessibility.cpp \
-    $$PWD/qwindowsuiaprovidercache.cpp \
-    $$PWD/qwindowsuiamainprovider.cpp \
-    $$PWD/qwindowsuiabaseprovider.cpp \
-    $$PWD/qwindowsuiavalueprovider.cpp \
-    $$PWD/qwindowsuiatextprovider.cpp \
-    $$PWD/qwindowsuiatextrangeprovider.cpp \
-    $$PWD/qwindowsuiatoggleprovider.cpp \
-    $$PWD/qwindowsuiaselectionprovider.cpp \
-    $$PWD/qwindowsuiaselectionitemprovider.cpp \
-    $$PWD/qwindowsuiainvokeprovider.cpp \
-    $$PWD/qwindowsuiarangevalueprovider.cpp \
-    $$PWD/qwindowsuiatableprovider.cpp \
-    $$PWD/qwindowsuiatableitemprovider.cpp \
-    $$PWD/qwindowsuiagridprovider.cpp \
-    $$PWD/qwindowsuiagriditemprovider.cpp \
-    $$PWD/qwindowsuiawindowprovider.cpp \
-    $$PWD/qwindowsuiaexpandcollapseprovider.cpp \
-    $$PWD/qwindowsuiautils.cpp
-
-HEADERS += \
-    $$PWD/qwindowsuiaaccessibility.h \
-    $$PWD/qwindowsuiaprovidercache.h \
-    $$PWD/qwindowsuiamainprovider.h \
-    $$PWD/qwindowsuiabaseprovider.h \
-    $$PWD/qwindowsuiavalueprovider.h \
-    $$PWD/qwindowsuiatextprovider.h \
-    $$PWD/qwindowsuiatextrangeprovider.h \
-    $$PWD/qwindowsuiatoggleprovider.h \
-    $$PWD/qwindowsuiaselectionprovider.h \
-    $$PWD/qwindowsuiaselectionitemprovider.h \
-    $$PWD/qwindowsuiainvokeprovider.h \
-    $$PWD/qwindowsuiarangevalueprovider.h \
-    $$PWD/qwindowsuiatableprovider.h \
-    $$PWD/qwindowsuiatableitemprovider.h \
-    $$PWD/qwindowsuiagridprovider.h \
-    $$PWD/qwindowsuiagriditemprovider.h \
-    $$PWD/qwindowsuiawindowprovider.h \
-    $$PWD/qwindowsuiaexpandcollapseprovider.h \
-    $$PWD/qwindowsuiautils.h
-
-mingw: QMAKE_USE *= uuid
diff --git a/src/plugins/platforms/windows/windows.pri b/src/plugins/platforms/windows/windows.pri
deleted file mode 100644
index 1cfcf314f3..0000000000
--- a/src/plugins/platforms/windows/windows.pri
+++ /dev/null
@@ -1,116 +0,0 @@
-# Note: OpenGL32 must precede Gdi32 as it overwrites some functions.
-LIBS += -lwinspool -limm32 -loleaut32
-
-QT_FOR_CONFIG += gui
-
-qtConfig(opengl):!qtConfig(dynamicgl): LIBS *= -lopengl32
-
-mingw: QMAKE_USE *= uuid
-
-LIBS += -lshlwapi -lwtsapi32
-
-QMAKE_USE_PRIVATE += \
-    advapi32 \
-    ole32 \
-    shell32 \
-    user32 \
-    winmm
-
-DEFINES *= QT_NO_CAST_FROM_ASCII QT_NO_FOREACH
-
-SOURCES += \
-    $$PWD/qwindowsapplication.cpp \
-    $$PWD/qwindowswindow.cpp \
-    $$PWD/qwindowsintegration.cpp \
-    $$PWD/qwindowscontext.cpp \
-    $$PWD/qwindowsscreen.cpp \
-    $$PWD/qwindowskeymapper.cpp \
-    $$PWD/qwindowsmousehandler.cpp \
-    $$PWD/qwindowspointerhandler.cpp \
-    $$PWD/qwindowsole.cpp \
-    $$PWD/qwindowsdropdataobject.cpp \
-    $$PWD/qwindowsmime.cpp \
-    $$PWD/qwindowsinternalmimedata.cpp \
-    $$PWD/qwindowscursor.cpp \
-    $$PWD/qwindowsinputcontext.cpp \
-    $$PWD/qwindowstheme.cpp \
-    $$PWD/qwindowsmenu.cpp \
-    $$PWD/qwindowsdialoghelpers.cpp \
-    $$PWD/qwindowsservices.cpp \
-    $$PWD/qwindowsnativeinterface.cpp \
-    $$PWD/qwindowsopengltester.cpp \
-    $$PWD/qwin10helpers.cpp
-
-HEADERS += \
-    $$PWD/qwindowsapplication.h \
-    $$PWD/qwindowscombase.h \
-    $$PWD/qwindowswindow.h \
-    $$PWD/qwindowsintegration.h \
-    $$PWD/qwindowscontext.h \
-    $$PWD/qwindowsscreen.h \
-    $$PWD/qwindowskeymapper.h \
-    $$PWD/qwindowsmousehandler.h \
-    $$PWD/qwindowspointerhandler.h \
-    $$PWD/qtwindowsglobal.h \
-    $$PWD/qwindowsole.h \
-    $$PWD/qwindowsdropdataobject.h \
-    $$PWD/qwindowsmime.h \
-    $$PWD/qwindowsinternalmimedata.h \
-    $$PWD/qwindowscursor.h \
-    $$PWD/qwindowsinputcontext.h \
-    $$PWD/qwindowstheme.h \
-    $$PWD/qwindowsmenu.h \
-    $$PWD/qwindowsdialoghelpers.h \
-    $$PWD/qwindowsservices.h \
-    $$PWD/qwindowsnativeinterface.h \
-    $$PWD/qwindowsopengltester.h \
-    $$PWD/qwindowsthreadpoolrunner.h \
-    $$PWD/qwin10helpers.h
-
-INCLUDEPATH += $$PWD
-
-qtConfig(opengl): HEADERS += $$PWD/qwindowsopenglcontext.h
-
-# Only WGL is supported in Qt 6, ANGLE is removed
-qtConfig(opengl) {
-    SOURCES += $$PWD/qwindowsglcontext.cpp
-    HEADERS += $$PWD/qwindowsglcontext.h
-}
-
-qtConfig(systemtrayicon) {
-    SOURCES += $$PWD/qwindowssystemtrayicon.cpp
-    HEADERS += $$PWD/qwindowssystemtrayicon.h
-}
-
-qtConfig(vulkan) {
-    SOURCES += $$PWD/qwindowsvulkaninstance.cpp
-    HEADERS += $$PWD/qwindowsvulkaninstance.h
-}
-
-qtConfig(clipboard) {
-    SOURCES += $$PWD/qwindowsclipboard.cpp
-    HEADERS += $$PWD/qwindowsclipboard.h
-    # drag and drop on windows only works if a clipboard is available
-    qtConfig(draganddrop) {
-        HEADERS += $$PWD/qwindowsdrag.h
-        SOURCES += $$PWD/qwindowsdrag.cpp
-    }
-}
-
-qtConfig(tabletevent) {
-    INCLUDEPATH += $$QT_SOURCE_TREE/src/3rdparty/wintab
-    HEADERS += $$PWD/qwindowstabletsupport.h
-    SOURCES += $$PWD/qwindowstabletsupport.cpp
-}
-
-qtConfig(sessionmanager) {
-    SOURCES += $$PWD/qwindowssessionmanager.cpp
-    HEADERS += $$PWD/qwindowssessionmanager.h
-}
-
-qtConfig(imageformat_png):RESOURCES += $$PWD/cursors.qrc
-
-RESOURCES += $$PWD/openglblacklists.qrc
-
-qtConfig(accessibility): include($$PWD/uiautomation/uiautomation.pri)
-
diff --git a/src/plugins/platforms/windows/windows.pro b/src/plugins/platforms/windows/windows.pro
deleted file mode 100644
index ea211beaef..0000000000
--- a/src/plugins/platforms/windows/windows.pro
+++ /dev/null
@@ -1,28 +0,0 @@
-TARGET = qwindows
-
-QT += core-private gui-private
-
-qtConfig(opengl): QT += opengl-private
-
-LIBS += -ldwmapi
-QMAKE_USE_PRIVATE += gdi32
-
-include(windows.pri)
-
-SOURCES +=  \
-    main.cpp \
-    qwindowsbackingstore.cpp \
-    qwindowsgdiintegration.cpp \
-    qwindowsgdinativeinterface.cpp
-
-HEADERS +=  \
-    qwindowsbackingstore.h \
-    qwindowsgdiintegration.h \
-    qwindowsgdinativeinterface.h
-
-OTHER_FILES += windows.json
-
-PLUGIN_TYPE = platforms
-PLUGIN_CLASS_NAME = QWindowsIntegrationPlugin
-!equals(TARGET, $$QT_DEFAULT_QPA_PLUGIN): PLUGIN_EXTENDS = -
-load(qt_plugin)