From b0060d1056d6d1752d91652261de97db909c7862 Mon Sep 17 00:00:00 2001
From: Oswald Buddenhagen <oswald.buddenhagen@qt.io>
Date: Mon, 31 Jul 2017 12:51:38 +0200
Subject: configure: un-namespace remaining non-inline configure tests

only few tests remain, and many of these were mis-classified anyway.

Change-Id: Ic3bc96928a0c79fe77b9ec10e6508d4822f18df2
Reviewed-by: Thiago Macieira <thiago.macieira@intel.com>
---
 config.tests/verifyspec/verifyspec.cpp |  1 +
 config.tests/verifyspec/verifyspec.pro | 37 ++++++++++++++++++++++++++++++++++
 2 files changed, 38 insertions(+)
 create mode 100644 config.tests/verifyspec/verifyspec.cpp
 create mode 100644 config.tests/verifyspec/verifyspec.pro

(limited to 'config.tests/verifyspec')

diff --git a/config.tests/verifyspec/verifyspec.cpp b/config.tests/verifyspec/verifyspec.cpp
new file mode 100644
index 0000000000..bd5560bf02
--- /dev/null
+++ b/config.tests/verifyspec/verifyspec.cpp
@@ -0,0 +1 @@
+int main(int, char **) {}
diff --git a/config.tests/verifyspec/verifyspec.pro b/config.tests/verifyspec/verifyspec.pro
new file mode 100644
index 0000000000..11a280e4ce
--- /dev/null
+++ b/config.tests/verifyspec/verifyspec.pro
@@ -0,0 +1,37 @@
+SOURCES = verifyspec.cpp
+
+# Provide a function to be used by mkspecs
+defineTest(deviceSanityCheckCompiler) {
+    equals(QMAKE_HOST.os, Windows): \
+        sfx = .exe
+    else: \
+        sfx =
+
+    # Build the compiler filename using the first value in QMAKE_CXX in order to
+    # support tools like ccache, which give QMAKE_CXX values of the form:
+    #     ccache <path_to_compiler>
+    compiler = $$first(QMAKE_CXX)$$sfx
+
+    # Check if the binary exists with an absolute path. Do this check
+    # before the CROSS_COMPILE empty check below to allow the mkspec
+    # to derive the compiler path from other device options.
+    exists($$compiler): return()
+
+    # Check for possible reasons of failure
+    # check if CROSS_COMPILE device-option is set
+    isEmpty(CROSS_COMPILE): \
+        error("CROSS_COMPILE needs to be set via -device-option CROSS_COMPILE=<path>")
+
+    # Check if QMAKE_CXX points to an executable.
+    ensurePathEnv()
+    for (dir, QMAKE_PATH_ENV) {
+        exists($$dir/$${compiler}): \
+            return()
+    }
+
+    # QMAKE_CXX does not point to a compiler.
+    error("Compiler $$QMAKE_CXX not found. Check the value of CROSS_COMPILE -device-option")
+}
+
+defined(qtConfSanitizeMkspec, test): \
+    qtConfSanitizeMkspec()
-- 
cgit v1.2.3