From f9048b3465d163a3c4e12fe6b9261d42a996b314 Mon Sep 17 00:00:00 2001
From: Qt4iOS <ian@mediator-software.com>
Date: Fri, 16 Mar 2012 15:00:33 +0000
Subject: Added mkspecs for iOS.
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Modified common MacOS gcc config for iOS compatibility. Added iOS
mkspecs for iOS devices and simulator using G++, LLVM-G++ or CLANG
compilers.

Change-Id: If0a0b1a3ce4e0dc4db319a315e227a9d31549399
Reviewed-by: Morten Johan Sørvig <morten.sorvig@nokia.com>
Reviewed-by: Lars Knoll <lars.knoll@nokia.com>
---
 mkspecs/common/ios/qmake.conf | 66 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 mkspecs/common/ios/qmake.conf

(limited to 'mkspecs/common/ios/qmake.conf')

diff --git a/mkspecs/common/ios/qmake.conf b/mkspecs/common/ios/qmake.conf
new file mode 100644
index 0000000000..8ee2575fb4
--- /dev/null
+++ b/mkspecs/common/ios/qmake.conf
@@ -0,0 +1,66 @@
+#
+# Common build settings for all iOS configurations
+#
+# Depends on:
+#
+#   QMAKE_IOS_XCODE_VERSION - set in mkspecs/common/ios/versions.conf
+#   QMAKE_IOS_SDK_VERSION   - set in mkspecs/common/ios/versions.conf
+#   QMAKE_IOSSIMULATOR_SDK_VERSION - set in mkspecs/common/ios/versions.conf
+#
+
+# iOS SDK device type
+!*simulator*: QMAKE_IOS_DEVICE_TYPE = iPhoneOS
+else {
+    QMAKE_IOS_DEVICE_TYPE = iPhoneSimulator
+
+    # Use simulator SDK version
+    QMAKE_IOS_SDK_VERSION = $$QMAKE_IOS_SIMULATOR_SDK_VERSION
+    QMAKE_IOS_SIMULATOR_SDK_VERSION =
+}
+
+!lessThan(QMAKE_IOS_XCODE_VERSION, "4.3") {
+    # Xcode 4.3+ is stored in /Applications
+    QMAKE_IOS_XCODE_PATH = /Applications/Xcode.app/Contents
+} else: QMAKE_IOS_XCODE_PATH =
+
+# iOS platform /Developer path
+QMAKE_IOS_DEV_PATH      = $$QMAKE_IOS_XCODE_PATH/Developer/Platforms/$${QMAKE_IOS_DEVICE_TYPE}.platform/Developer
+QMAKE_IOS_XCODE_PATH    =
+
+# iOS platform SDK path
+QMAKE_IOS_SDK           = $$QMAKE_IOS_DEV_PATH/SDKs/$${QMAKE_IOS_DEVICE_TYPE}$${QMAKE_IOS_SDK_VERSION}.sdk
+QMAKE_IOS_DEV_PATH      =
+QMAKE_IOS_DEVICE_TYPE   =
+
+QMAKE_CFLAGS           += -isysroot $$QMAKE_IOS_SDK
+QMAKE_CXXFLAGS         += -isysroot $$QMAKE_IOS_SDK
+QMAKE_OBJECTIVE_CFLAGS += -isysroot $$QMAKE_IOS_SDK
+QMAKE_LFLAGS           += -Wl,-syslibroot,$$QMAKE_IOS_SDK
+QMAKE_IOS_SDK           =
+
+# Basic iOS frameworks needed for any GUI app
+QMAKE_LFLAGS           += -framework Foundation -framework UIKit -framework QuartzCore -lz
+
+# OpenGL ES1
+QMAKE_INCDIR_OPENGL_ES1 = $$QMAKE_IOS_SDK/System/Library/Frameworks/OpenGLES.framework/Headers
+QMAKE_LIBDIR_OPENGL_ES1 =
+QMAKE_LIBS_OPENGL_ES1   = -framework OpenGLES
+
+# OpenGL ES2
+QMAKE_INCDIR_OPENGL_ES2 = $$QMAKE_IOS_SDK/System/Library/Frameworks/OpenGLES.framework/Headers
+QMAKE_LIBDIR_OPENGL_ES2 =
+QMAKE_LIBS_OPENGL_ES2   = -framework OpenGLES
+
+# No desktop OpenGL
+QMAKE_INCDIR_OPENGL     =
+QMAKE_LIBS_OPENGL       =
+QMAKE_LIBS_OPENGL_QT    =
+
+# Compiler-specific flags
+!*-g++* {
+    # Objective-C/C++ precompile flags
+    QMAKE_OBJCFLAGS_PRECOMPILE = -x objective-c-header -c ${QMAKE_PCH_INPUT} -o ${QMAKE_PCH_OUTPUT}
+    QMAKE_OBJCFLAGS_USE_PRECOMPILE = $$QMAKE_CFLAGS_USE_PRECOMPILE
+    QMAKE_OBJCXXFLAGS_PRECOMPILE = -x objective-c++-header -c ${QMAKE_PCH_INPUT} -o ${QMAKE_PCH_OUTPUT}
+    QMAKE_OBJCXXFLAGS_USE_PRECOMPILE = $$QMAKE_CFLAGS_USE_PRECOMPILE
+}
-- 
cgit v1.2.3