From 71616d2c7a20b6f54747f66fe2fb6cef317667f5 Mon Sep 17 00:00:00 2001
From: Donald Carr <donald.carr@nokia.com>
Date: Wed, 28 Mar 2012 19:23:50 +0000
Subject: device: Add device support for the Broadcom Raspberry PI
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Add mkspec for the Raspberry PI platform to be used in conjunction with the
-device support in configure. This allows you to build Qt with the
application libraries provided by the Raspberry PI foundation.

The Raspberry PI is described here:

http://en.wikipedia.org/wiki/Raspberry_Pi

and its use with Qt is documented here:

http://wiki.qt-project.org/Devices/RaspberryPi

Change-Id: Ib8d11d0a469edaaf34ccc04cf33a42a725fc2bdb
Reviewed-by: Girish Ramakrishnan <girish.1.ramakrishnan@nokia.com>
Reviewed-by: Samuel Rødal <samuel.rodal@nokia.com>
---
 mkspecs/devices/linux-rasp-pi-g++/qmake.conf | 56 ++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 mkspecs/devices/linux-rasp-pi-g++/qmake.conf

(limited to 'mkspecs/devices/linux-rasp-pi-g++/qmake.conf')

diff --git a/mkspecs/devices/linux-rasp-pi-g++/qmake.conf b/mkspecs/devices/linux-rasp-pi-g++/qmake.conf
new file mode 100644
index 0000000000..326d6b3b61
--- /dev/null
+++ b/mkspecs/devices/linux-rasp-pi-g++/qmake.conf
@@ -0,0 +1,56 @@
+#
+# qmake configuration for Broadcom's Raspberry PI
+# http://wiki.qt-project.org/Devices/RaspberryPi
+
+!exists($$[QT_SYSROOT]/usr/include/libudev.h) {
+    message("Keyboard support requires udev")
+    message("Install libudev-dev in your rootfs")
+    error()
+}
+
+MAKEFILE_GENERATOR  = UNIX
+TARGET_PLATFORM     = unix
+TEMPLATE            = app
+CONFIG              += qt warn_on release incremental link_prl gdb_dwarf_index
+QT                  += core gui
+QMAKE_INCREMENTAL_STYLE = sublib
+
+include(../../common/linux.conf)
+include(../../common/gcc-base-unix.conf)
+include(../../common/g++-unix.conf)
+
+load(device_config)
+
+QMAKE_CC                = $${CROSS_COMPILE}gcc
+QMAKE_CXX               = $${CROSS_COMPILE}g++
+QMAKE_LINK              = $${QMAKE_CXX}
+QMAKE_LINK_SHLIB        = $${QMAKE_CXX}
+
+# modifications to linux.conf
+QMAKE_AR                = $${CROSS_COMPILE}ar cqs
+QMAKE_OBJCOPY           = $${CROSS_COMPILE}objcopy
+QMAKE_STRIP             = $${CROSS_COMPILE}strip
+
+#Circular dependency in GLES2 <-> EGL requires the following abomination
+QMAKE_LIBS_EGL          = -L$$[QT_SYSROOT]/opt/vc/lib -lWFC -lGLESv2 -lEGL -lbcm_host -lopenmaxil
+QMAKE_LIBS_OPENGL_ES2   = $${QMAKE_LIBS_EGL}
+QMAKE_LIBS_OPENVG       = $${QMAKE_LIBS_EGL}
+
+QMAKE_INCDIR_EGL        = $$[QT_SYSROOT]/opt/vc/include
+QMAKE_INCDIR_OPENGL_ES2 = $${QMAKE_INCDIR_EGL}
+
+QMAKE_CFLAGS_RELEASE    += \
+                          -mfloat-abi=softfp \
+                          -mfpu=vfp \
+                          -mtune=arm1176jzf-s \
+                          -march=armv6zk \
+                          -mabi=aapcs-linux
+
+QMAKE_CXXFLAGS_RELEASE = $$QMAKE_CFLAGS_RELEASE
+
+EGLFS_PLATFORM_HOOKS_SOURCES = $$PWD/qeglfs_hooks.cpp
+
+# Sanity check
+deviceSanityCheckCompiler()
+
+load(qt_config)
-- 
cgit v1.2.3