From aad3410864887d59ecd7d43ae7cf646a20b13c2b Mon Sep 17 00:00:00 2001
From: Oswald Buddenhagen <oswald.buddenhagen@nokia.com>
Date: Fri, 14 Sep 2012 15:38:56 +0200
Subject: factor out qtAddTargetEnv()

Change-Id: Ib0517da54da98de4b1f2ee7d80bee22316231091
Reviewed-by: Joerg Bornemann <joerg.bornemann@digia.com>
---
 mkspecs/features/qt_functions.prf | 31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)

(limited to 'mkspecs/features/qt_functions.prf')

diff --git a/mkspecs/features/qt_functions.prf b/mkspecs/features/qt_functions.prf
index 58c35ddd41..c700a37e5a 100644
--- a/mkspecs/features/qt_functions.prf
+++ b/mkspecs/features/qt_functions.prf
@@ -204,6 +204,37 @@ defineTest(qtAddToolEnv) {
     export($$1)
 }
 
+defineTest(qtAddTargetEnv) {
+    deps = $$resolve_depends(QT, "QT.")
+    !isEmpty(deps) {
+        plugin_paths =
+        for(dep, deps) {
+            deppath += $$shell_path($$eval(QT.$${dep}.libs))
+            for(rpath, QT.$${dep}.rpath_link): \
+                deppath += $$shell_path($$rpath)
+            plugin_paths += $$eval(QT.$${dep}.plugin_path) $$eval(QT.$${dep}.plugins)
+        }
+        equals(QMAKE_HOST.os, Windows): \
+            deppath.name = PATH
+        else:contains(QMAKE_HOST.os, Linux|FreeBSD): \
+            deppath.name = LD_LIBRARY_PATH
+        else:equals(QMAKE_HOST.os, Darwin): \
+            deppath.name = DYLD_LIBRARY_PATH
+        else: \
+            error("Operating system not supported.")
+        deppath.value = $$unique(deppath)
+        deppath.CONFIG = prepend
+        pluginpath.name = QT_PLUGIN_PATH
+        pluginpath.value =
+        plugin_paths = $$unique(plugin_paths)
+        for(ppath, plugin_paths): \
+            exists($$ppath): \
+                pluginpath.value += $$shell_path($$ppath)
+        QT_TOOL_ENV += deppath pluginpath
+    }
+    qtAddToolEnv($$1, $$QT_TOOL_ENV)
+}
+
 defineReplace(pkgConfigExecutable) {
     isEmpty(PKG_CONFIG) {
         PKG_CONFIG = pkg-config
-- 
cgit v1.2.3