From a8814fcb697893f6ab151342727ea0867f6fec21 Mon Sep 17 00:00:00 2001
From: axis <qt-info@nokia.com>
Date: Fri, 27 May 2011 10:10:36 +0200
Subject: Made qpluginbase.pri into a feature profile.

This enables other modules to use it without having access to the
QtBase sources.

Change-Id: I0a588b2e14ca88fa068c7c2bcc69ff669444f6c6
Task: QTBUG-19585
Reviewed-on: http://codereview.qt.nokia.com/237
Reviewed-by: Qt Sanity Bot <qt_sanity_bot@ovi.com>
Reviewed-by: Rohan McGovern <rohan.mcgovern@nokia.com>
---
 mkspecs/features/qt_plugin.prf | 41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 mkspecs/features/qt_plugin.prf

(limited to 'mkspecs')

diff --git a/mkspecs/features/qt_plugin.prf b/mkspecs/features/qt_plugin.prf
new file mode 100644
index 0000000000..c4eaab8147
--- /dev/null
+++ b/mkspecs/features/qt_plugin.prf
@@ -0,0 +1,41 @@
+TEMPLATE = lib
+isEmpty(QT_MAJOR_VERSION) {
+   VERSION=5.0.0
+} else {
+   VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}
+}
+CONFIG += qt plugin
+
+win32|mac:!wince*:!win32-msvc:!macx-xcode:CONFIG += debug_and_release
+TARGET = $$qtLibraryTarget($$TARGET)
+contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
+
+load(qt_targets)
+
+wince*:LIBS += $$QMAKE_LIBS_GUI
+
+symbian: {
+    TARGET.EPOCALLOWDLLDATA=1
+    TARGET.CAPABILITY = All -Tcb
+    TARGET = $${TARGET}$${QT_LIBINFIX}
+    load(armcc_warnings)
+
+    # Make partial upgrade SIS file for Qt plugin dll's
+    # Partial upgrade SIS file
+    vendorinfo = \
+        "; Localised Vendor name" \
+        "%{\"Nokia\"}" \
+        " " \
+        "; Unique Vendor name" \
+        ":\"Nokia, Qt\"" \
+        " "
+    isEmpty(QT_LIBINFIX): PARTIAL_UPGRADE_UID = 0x2001E61C
+    else: PARTIAL_UPGRADE_UID = 0xE001E61C
+
+    pu_header = "; Partial upgrade package for testing $${TARGET} changes without reinstalling everything" \
+                "$${LITERAL_HASH}{\"$${TARGET}\"}, ($$PARTIAL_UPGRADE_UID), $${QT_MAJOR_VERSION},$${QT_MINOR_VERSION},$${QT_PATCH_VERSION}, TYPE=PU"
+    partial_upgrade.pkg_prerules = pu_header vendorinfo
+    partial_upgrade.files = $$QMAKE_LIBDIR_QT/$${TARGET}.dll
+    partial_upgrade.path = c:/sys/bin
+    DEPLOYMENT += partial_upgrade
+}
-- 
cgit v1.2.3