QT_QPA_DEFAULT_PLATFORM = eglfs

MAKEFILE_GENERATOR      = UNIX
CONFIG                 += incremental
QMAKE_INCREMENTAL_STYLE = sublib

include(../../common/linux.conf)
include(../../common/gcc-base-unix.conf)
include(../../common/g++-unix.conf)

!load(device_config) {
    error(Could not successfully load device configuration)
}

# modifications to g++-unix.conf
QMAKE_CC                = $${CROSS_COMPILE}gcc
QMAKE_CXX               = $${CROSS_COMPILE}g++
QMAKE_LINK              = $${QMAKE_CXX}
QMAKE_LINK_SHLIB        = $${QMAKE_CXX}

# modifications to linux.conf
QMAKE_AR                = $${CROSS_COMPILE}ar cqs
QMAKE_OBJCOPY           = $${CROSS_COMPILE}objcopy
QMAKE_NM                = $${CROSS_COMPILE}nm -P
QMAKE_STRIP             = $${CROSS_COMPILE}strip

# modifications to gcc-base.conf
QMAKE_AR_LTCG           = $${CROSS_COMPILE}gcc-ar cqs
QMAKE_NM_LTCG           = $${CROSS_COMPILE}gcc-nm -P

contains(DISTRO_OPTS, deb-multi-arch): \
    QMAKE_PKG_CONFIG = $${CROSS_COMPILE}pkg-config