#
# qmake configuration for Broadcom's Raspberry PI
# http://wiki.qt-project.org/Devices/RaspberryPi

include(../common/linux_device_pre.conf)

QMAKE_LFLAGS            += -Wl,-rpath-link,$$[QT_SYSROOT]/opt/vc/lib

QMAKE_LIBDIR_OPENGL_ES2 = $$[QT_SYSROOT]/opt/vc/lib
QMAKE_LIBDIR_EGL        = $$QMAKE_LIBDIR_OPENGL_ES2

QMAKE_INCDIR_EGL        = $$[QT_SYSROOT]/opt/vc/include
QMAKE_INCDIR_OPENGL_ES2 = $${QMAKE_INCDIR_EGL}

QMAKE_LIBS_EGL          = -lEGL -lGLESv2

contains(DISTRO, wheezy) {
    DISTRO_OPTS += deb-multi-arch
} else:contains(DISTRO, bsquask) {
    DISTRO_OPTS += hard-float
} else:contains(DISTRO, arch) {
    #On principle: no wizardry required
} else {
    #Debian Squeeze: Legacy circular dependency
    QMAKE_LIBS_OPENGL_ES2          = -lGLESv2 -lEGL
}

QMAKE_CFLAGS            += \
                          -marm \
                          -mfpu=vfp \
                          -mtune=arm1176jzf-s \
                          -march=armv6zk \
                          -mabi=aapcs-linux

QMAKE_CXXFLAGS          = $$QMAKE_CFLAGS

EGLFS_PLATFORM_HOOKS_SOURCES = $$PWD/qeglfshooks_pi.cpp
EGLFS_PLATFORM_HOOKS_LIBS = -lbcm_host

include(../common/linux_device_post.conf)

load(qt_config)