summaryrefslogtreecommitdiffstats
path: root/cmake/FindWrapSystemPCRE2.cmake
blob: cdf2cbfc54fc5a5a39d14bd863296465f60b8cbd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
# Copyright (C) 2022 The Qt Company Ltd.
# SPDX-License-Identifier: LicenseRef-Qt-Commercial OR GPL-3.0-only WITH Qt-GPL-exception-1.0

if(TARGET WrapSystemPCRE2::WrapSystemPCRE2)
    set(WrapSystemPCRE2_FOUND TRUE)
    return()
endif()
set(WrapSystemPCRE2_REQUIRED_VARS __pcre2_found)

find_package(PCRE2 ${${CMAKE_FIND_PACKAGE_NAME}_FIND_VERSION} COMPONENTS 16BIT QUIET)

# TODO: pcre2-16 is not the target name provided by the upstream Config file. It is PCRE2::16BIT.
# https://github.com/PCRE2Project/pcre2/blob/2410fbe3869cab403f02b94caa9ab37ee9f5854b/cmake/pcre2-config.cmake.in#L122
# We don't strictly need to handle that though, because the pkg-config code path below still
# finds the correct libraries.
set(__pcre2_target_name "PCRE2::pcre2-16")
if(PCRE2_FOUND AND TARGET "${__pcre2_target_name}")
  # Hunter case.
  set(__pcre2_found TRUE)
  if(PCRE2_VERSION)
      set(WrapSystemPCRE2_VERSION "${PCRE2_VERSION}")
  endif()
endif()

if(NOT __pcre2_found)
  list(PREPEND WrapSystemPCRE2_REQUIRED_VARS PCRE2_LIBRARIES PCRE2_INCLUDE_DIRS)

  find_package(PkgConfig QUIET)
  pkg_check_modules(PC_PCRE2 QUIET libpcre2-16)

  find_path(PCRE2_INCLUDE_DIRS
            NAMES pcre2.h
            HINTS ${PC_PCRE2_INCLUDEDIR})
  find_library(PCRE2_LIBRARY_RELEASE
              NAMES pcre2-16
              HINTS ${PC_PCRE2_LIBDIR})
  find_library(PCRE2_LIBRARY_DEBUG
              NAMES pcre2-16d pcre2-16
              HINTS ${PC_PCRE2_LIBDIR})
  include(SelectLibraryConfigurations)
  select_library_configurations(PCRE2)

  if(PC_PCRE2_VERSION)
      set(WrapSystemPCRE2_VERSION "${PC_PCRE2_VERSION}")
  endif()

  if (PCRE2_LIBRARIES AND PCRE2_INCLUDE_DIRS)
      set(__pcre2_found TRUE)
  endif()
endif()

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(WrapSystemPCRE2
                                  REQUIRED_VARS ${WrapSystemPCRE2_REQUIRED_VARS}
                                  VERSION_VAR WrapSystemPCRE2_VERSION)
if(WrapSystemPCRE2_FOUND)
    add_library(WrapSystemPCRE2::WrapSystemPCRE2 INTERFACE IMPORTED)
    if(TARGET "${__pcre2_target_name}")
        target_link_libraries(WrapSystemPCRE2::WrapSystemPCRE2 INTERFACE "${__pcre2_target_name}")
    else()
        target_link_libraries(WrapSystemPCRE2::WrapSystemPCRE2 INTERFACE ${PCRE2_LIBRARIES})
        target_include_directories(WrapSystemPCRE2::WrapSystemPCRE2 INTERFACE ${PCRE2_INCLUDE_DIRS})
    endif()
endif()
unset(__pcre2_target_name)
unset(__pcre2_found)