summaryrefslogtreecommitdiffstats
path: root/cmake/FindZSTD.cmake
blob: 040e8c1642a911ab6c7d7691e5278a29bd8a178f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
#.rst:
# FindZstd
# ---------
#
# Try to locate the Zstd library.
# If found, this will define the following variables:
#
# ``ZSTD_FOUND``
#     True if the zstd library is available
# ``ZSTD_INCLUDE_DIRS``
#     The zstd include directories
# ``ZSTD_LIBRARIES``
#     The zstd libraries for linking
#
# If ``ZSTD_FOUND`` is TRUE, it will also define the following
# imported target:
#
# ``ZSTD::ZSTD``
#     The zstd library

find_package(PkgConfig)
pkg_check_modules(PC_ZSTD QUIET libzstd)

find_path(ZSTD_INCLUDE_DIRS
          NAMES zstd.h
          HINTS ${PC_ZSTD_INCLUDEDIR}
          PATH_SUFFIXES zstd)

find_library(ZSTD_LIBRARIES
             NAMES zstd
             HINTS ${PC_ZSTD_LIBDIR}
)

include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(ZSTD DEFAULT_MSG ZSTD_LIBRARIES ZSTD_INCLUDE_DIRS)

if(ZSTD_FOUND AND NOT TARGET ZSTD::ZSTD)
  add_library(ZSTD::ZSTD UNKNOWN IMPORTED)
  set_target_properties(ZSTD::ZSTD PROPERTIES
                        IMPORTED_LOCATION "${ZSTD_LIBRARIES}"
                        INTERFACE_INCLUDE_DIRECTORIES "${ZSTD_INCLUDE_DIRS}")
endif()

mark_as_advanced(ZSTD_INCLUDE_DIRS ZSTD_LIBRARIES)

set_package_properties(ZSTD PROPERTIES
  URL "https://github.com/facebook/zstd"
  DESCRIPTION "ZSTD compression library")