summaryrefslogtreecommitdiffstats
path: root/examples/network/network.pro
blob: 68200efb1869667dcfa08c4d578f4979689ba513 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
requires(qtHaveModule(network))

TEMPLATE      = subdirs
SUBDIRS       = \
                download \
                downloadmanager
!integrity: SUBDIRS += dnslookup
qtHaveModule(widgets) {
    SUBDIRS +=  \
                blockingfortuneclient \
                broadcastreceiver \
                broadcastsender \
                http \
                loopback \
                threadedfortuneserver \
                googlesuggest \
                torrent \
                multicastreceiver \
                multicastsender

    load(qfeatures)
    !contains(QT_DISABLED_FEATURES, bearermanagement) {
        # no QProcess
        !vxworks:!qnx:!winrt:!integrity: SUBDIRS += network-chat

        SUBDIRS += \
                bearermonitor \
                fortuneclient \
                fortuneserver

    }

    qtConfig(openssl): SUBDIRS += securesocketclient
    qtConfig(openssl-linked): SUBDIRS += securesocketclient
    qtConfig(sctp): SUBDIRS += multistreamserver multistreamclient
}

EXAMPLE_FILES = shared