summaryrefslogtreecommitdiffstats
path: root/mkspecs/devices/common/linux_device_pre.conf
blob: 8c6c87d0b79e4fbfeaf0124d0a666eed525ea7e5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
QT_QPA_DEFAULT_PLATFORM = eglfs

MAKEFILE_GENERATOR      = UNIX
CONFIG                 += incremental
QMAKE_INCREMENTAL_STYLE = sublib

include(../../common/linux.conf)
include(../../common/gcc-base-unix.conf)
include(../../common/g++-unix.conf)

!load(device_config) {
    error(Could not successfully load device configuration)
}

# modifications to g++-unix.conf
QMAKE_CC                = $${CROSS_COMPILE}gcc
QMAKE_CXX               = $${CROSS_COMPILE}g++
QMAKE_LINK              = $${QMAKE_CXX}
QMAKE_LINK_SHLIB        = $${QMAKE_CXX}

# modifications to linux.conf
QMAKE_AR                = $${CROSS_COMPILE}ar cqs
QMAKE_OBJCOPY           = $${CROSS_COMPILE}objcopy
QMAKE_NM                = $${CROSS_COMPILE}nm -P
QMAKE_STRIP             = $${CROSS_COMPILE}strip

contains(DISTRO_OPTS, deb-multi-arch): \
    QMAKE_PKG_CONFIG = $${CROSS_COMPILE}pkg-config