summaryrefslogtreecommitdiffstats
path: root/mkspecs/features/default_pre.prf
blob: a247b46a72e17a3de420a15ec1fc600b3db4e98f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
# This file is loaded by qmake right before each actual project file.
# Note that evaluating variable assignments from the command line
# still happens in between these two steps.

load(exclusive_builds)
CONFIG = \
    lex yacc debug exceptions depend_includepath \
    testcase_targets import_plugins import_qpa_plugin \
    $$CONFIG

contains(QT_CONFIG, c++11):lessThan(QT_COMPILER_STDCXX, 201103): CONFIG += c++11

!build_pass:defined(QT_EDITION, var):!equals(QT_EDITION, "OpenSource"):!equals(QT_EDITION, "Preview") {
    #
    # call license checker (but cache result for one day)
    #
    today = $$section(_DATE_, " ", 0, 2)
    !isEqual(QMAKE_LICHECK_TIMESTAMP, $$today) {
        !system("$$system_quote($$system_path($$[QT_HOST_BINS/src]/$$QT_LICHECK)) check" \
                "$$QT_RELEASE_DATE $$[QMAKE_SPEC] $$[QMAKE_XSPEC]"): \
            error("License check failed! Giving up ...")

        cache(QMAKE_LICHECK_TIMESTAMP, set stash, today)
    }
    unset(today)
}