mkspecs/features/qmake_use.prf


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

suffix =
for(ever) {
    QMAKE_USE$${suffix} = $$unique(QMAKE_USE$${suffix})
    for (use, QMAKE_USE$${suffix}) {
        use = $$split(use, /)
        name = $$take_first(use)
        nu = $$upper($$name)
        debug: \
            libs = $$eval(QMAKE_LIBS_$${nu}_DEBUG)
        else: \
            libs = $$eval(QMAKE_LIBS_$${nu}_RELEASE)
        libs += $$eval(QMAKE_LIBS_$$nu)
        libdir = $$eval(QMAKE_LIBDIR_$$nu)
        defines = $$eval(QMAKE_DEFINES_$${nu})
        includes = $$eval(QMAKE_INCDIR_$${nu})

        isEmpty(libs):isEmpty(defines):isEmpty(includes): \
            error("Library '$$name' is not defined.")

        !contains(use, nolink) {
            QMAKE_LIBDIR += $$libdir
            LIBS$${suffix} += $$libs
        }
        !contains(use, linkonly) {
            DEFINES += $$defines
            INCLUDEPATH += $$includes
        }
    }
    !isEmpty(suffix): break()
    suffix = "_PRIVATE"
}