summaryrefslogtreecommitdiffstats
path: root/mkspecs/features/uikit/sdk.prf
blob: 54674eb3960085cda36e1c36c2e03010bfdb0783 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29

# In case the user sets the SDK manually
contains(QMAKE_MAC_SDK, ^$${simulator.sdk}.*) {
    !isEmpty(QT_VERSION):qtConfig(simulator_and_device): \
        error("Simulator is handled automatically for simulator_and_device")

    CONFIG += simulator $${simulator.sdk}
}

build_pass:simulator: \
    QMAKE_MAC_SDK ~= s,^$${device.sdk},$${simulator.sdk},

load(sdk)

macx-xcode {
    sdk_path_device.name = "QMAKE_MAC_SDK_PATH[sdk=$${device.sdk}*]"
    sdk_path_device.value = $$xcodeSDKInfo(Path, $${device.sdk})
    sdk_path_simulator.name = "QMAKE_MAC_SDK_PATH[sdk=$${simulator.sdk}*]"
    sdk_path_simulator.value = $$xcodeSDKInfo(Path, $${simulator.sdk})
    QMAKE_MAC_XCODE_SETTINGS += sdk_path_device sdk_path_simulator
    QMAKE_MAC_SDK_PATH = "$(QMAKE_MAC_SDK_PATH)"

    sdk_platform_path_device.name = "QMAKE_MAC_SDK_PLATFORM_PATH[sdk=$${device.sdk}*]"
    sdk_platform_path_device.value = $$xcodeSDKInfo(PlatformPath, $${device.sdk})
    sdk_platform_path_simulator.name = "QMAKE_MAC_SDK_PLATFORM_PATH[sdk=$${simulator.sdk}*]"
    sdk_platform_path_simulator.value = $$xcodeSDKInfo(PlatformPath, $${simulator.sdk})
    QMAKE_MAC_XCODE_SETTINGS += sdk_platform_path_device sdk_platform_path_simulator
    QMAKE_MAC_SDK_PLATFORM_PATH = "$(QMAKE_MAC_SDK_PLATFORM_PATH)"
}