summaryrefslogtreecommitdiffstats
path: root/src/gui/painting/painting.pri
blob: fcf6488eddf3d7e7880cca40275926b1f1c2aca0 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
# Qt gui library, paint module

HEADERS += \
        painting/qbackingstore.h \
        painting/qbezier_p.h \
        painting/qblendfunctions_p.h \
        painting/qblittable_p.h \
        painting/qbrush.h \
        painting/qcolor.h \
        painting/qcolor_p.h \
        painting/qcolormatrix_p.h \
        painting/qcolorspace.h \
        painting/qcolorspace_p.h \
        painting/qcolortransferfunction_p.h \
        painting/qcolortransfertable_p.h \
        painting/qcolortransform.h \
        painting/qcolortransform_p.h \
        painting/qcolortrc_p.h \
        painting/qcolortrclut_p.h \
        painting/qcosmeticstroker_p.h \
        painting/qdatabuffer_p.h \
        painting/qdrawhelper_p.h \
        painting/qdrawhelper_x86_p.h \
        painting/qdrawingprimitive_sse2_p.h \
        painting/qemulationpaintengine_p.h \
        painting/qfixed_p.h \
        painting/qgrayraster_p.h \
        painting/qicc_p.h \
        painting/qmatrix.h \
        painting/qmemrotate_p.h \
        painting/qoutlinemapper_p.h \
        painting/qpagedpaintdevice.h \
        painting/qpagedpaintdevice_p.h \
        painting/qpagelayout.h \
        painting/qpagesize.h \
        painting/qpaintdevice.h \
        painting/qpaintengine.h \
        painting/qpaintengine_p.h \
        painting/qpaintengineex_p.h \
        painting/qpaintengine_blitter_p.h \
        painting/qpaintengine_raster_p.h \
        painting/qpainter.h \
        painting/qpainter_p.h \
        painting/qpainterpath.h \
        painting/qpainterpath_p.h \
        painting/qvectorpath_p.h \
        painting/qpathclipper_p.h \
        painting/qpdf_p.h \
        painting/qpdfwriter.h \
        painting/qpen.h \
        painting/qpolygon.h \
        painting/qpolygonclipper_p.h \
        painting/qrasterdefs_p.h \
        painting/qrasterizer_p.h \
        painting/qrbtree_p.h \
        painting/qregion.h \
        painting/qrgb.h \
        painting/qrgba64.h \
        painting/qrgba64_p.h \
        painting/qstroker_p.h \
        painting/qtextureglyphcache_p.h \
        painting/qtransform.h \
        painting/qtriangulatingstroker_p.h \
        painting/qtriangulator_p.h \
        painting/qplatformbackingstore.h \
        painting/qpathsimplifier_p.h


SOURCES += \
        painting/qbackingstore.cpp \
        painting/qbezier.cpp \
        painting/qblendfunctions.cpp \
        painting/qblittable.cpp \
        painting/qbrush.cpp \
        painting/qcolor.cpp \
        painting/qcolorspace.cpp \
        painting/qcolortransform.cpp \
        painting/qcolortrclut.cpp \
        painting/qcompositionfunctions.cpp \
        painting/qcosmeticstroker.cpp \
        painting/qdrawhelper.cpp \
        painting/qemulationpaintengine.cpp \
        painting/qgrayraster.c \
        painting/qicc.cpp \
        painting/qimagescale.cpp \
        painting/qmatrix.cpp \
        painting/qmemrotate.cpp \
        painting/qoutlinemapper.cpp \
        painting/qpagedpaintdevice.cpp \
        painting/qpagelayout.cpp \
        painting/qpagesize.cpp \
        painting/qpaintdevice.cpp \
        painting/qpaintengine.cpp \
        painting/qpaintengineex.cpp \
        painting/qpaintengine_blitter.cpp \
        painting/qpaintengine_raster.cpp \
        painting/qpainter.cpp \
        painting/qpainterpath.cpp \
        painting/qpathclipper.cpp \
        painting/qpdf.cpp \
        painting/qpdfwriter.cpp \
        painting/qpen.cpp \
        painting/qpolygon.cpp \
        painting/qrasterizer.cpp \
        painting/qregion.cpp \
        painting/qstroker.cpp \
        painting/qtextureglyphcache.cpp \
        painting/qtransform.cpp \
        painting/qtriangulatingstroker.cpp \
        painting/qtriangulator.cpp \
        painting/qplatformbackingstore.cpp \
        painting/qpathsimplifier.cpp

webgradients.files = painting/webgradients.binaryjson
webgradients.prefix = qgradient
webgradients.base = painting

RESOURCES += \
        painting/qpdf.qrc \
        webgradients

darwin {
    HEADERS += painting/qcoregraphics_p.h
    SOURCES += painting/qcoregraphics.mm
}

qtConfig(cssparser) {
    SOURCES += \
        painting/qcssutil.cpp
}

# Causes internal compiler errors with at least GCC 5.3.1:
gcc:equals(QT_GCC_MAJOR_VERSION, 5) {
    SOURCES -= painting/qdrawhelper.cpp
    NO_PCH_SOURCES += painting/qdrawhelper.cpp
}

!android {
    SSE2_SOURCES += painting/qdrawhelper_sse2.cpp
    SSSE3_SOURCES += painting/qdrawhelper_ssse3.cpp
    SSE4_1_SOURCES += painting/qdrawhelper_sse4.cpp \
                      painting/qimagescale_sse4.cpp
    ARCH_HASWELL_SOURCES += painting/qdrawhelper_avx2.cpp

    NEON_SOURCES += painting/qdrawhelper_neon.cpp painting/qimagescale_neon.cpp
    NEON_HEADERS += painting/qdrawhelper_neon_p.h
}
!uikit:!win32:contains(QT_ARCH, "arm"): CONFIG += no_clang_integrated_as
!android:!uikit:!win32:!integrity:!contains(QT_ARCH, "arm64") {
    NEON_ASM += ../3rdparty/pixman/pixman-arm-neon-asm.S painting/qdrawhelper_neon_asm.S
    DEFINES += ENABLE_PIXMAN_DRAWHELPERS
}

!android {
    MIPS_DSP_SOURCES += painting/qdrawhelper_mips_dsp.cpp
    MIPS_DSP_HEADERS += painting/qdrawhelper_mips_dsp_p.h painting/qt_mips_asm_dsp_p.h
    MIPS_DSP_ASM += painting/qdrawhelper_mips_dsp_asm.S
    MIPS_DSPR2_ASM += painting/qdrawhelper_mips_dspr2_asm.S
} else {
    # see https://developer.android.com/ndk/guides/abis
    x86 | x86_64 {
        DEFINES += QT_COMPILER_SUPPORTS_SSE2 QT_COMPILER_SUPPORTS_SSE3 QT_COMPILER_SUPPORTS_SSSE3
        SOURCES += painting/qdrawhelper_sse2.cpp painting/qdrawhelper_ssse3.cpp
    }
    x86_64 {
        DEFINES += QT_COMPILER_SUPPORTS_SSE4_1 QT_COMPILER_SUPPORTS_SSE4_2
        SOURCES += painting/qdrawhelper_sse4.cpp painting/qimagescale_sse4.cpp
    }
    arm64-v8a {
        SOURCES += painting/qdrawhelper_neon.cpp painting/qimagescale_neon.cpp
        HEADERS += painting/qdrawhelper_neon_p.h
    }
}

include($$PWD/../../3rdparty/zlib_dependency.pri)