summaryrefslogtreecommitdiffstats
path: root/src/platformsupport/platformsupport.pro
blob: f3f2c1c99a2351bfb2b5b9b7986042c0b7f3d050 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
TEMPLATE = subdirs
QT_FOR_CONFIG += gui-private

SUBDIRS = \
    edid \
    eventdispatchers \
    devicediscovery \
    fbconvenience \
    themes

qtConfig(freetype)|darwin|win32: \
    SUBDIRS += fontdatabases

qtConfig(evdev)|qtConfig(tslib)|qtConfig(libinput) {
    SUBDIRS += input
    input.depends += devicediscovery
}

unix:!darwin: \
    SUBDIRS += services

qtConfig(opengl): \
    SUBDIRS += platformcompositor
qtConfig(egl): \
    SUBDIRS += eglconvenience
qtConfig(xlib):qtConfig(opengl):!qtConfig(opengles2): \
    SUBDIRS += glxconvenience
qtConfig(kms): \
    SUBDIRS += kmsconvenience

qtConfig(accessibility) {
    SUBDIRS += accessibility
    qtConfig(accessibility-atspi-bridge) {
        SUBDIRS += linuxaccessibility
        linuxaccessibility.depends += accessibility
    }
}

darwin {
    SUBDIRS += \
        clipboard \
        graphics
    macos: \
        SUBDIRS += cglconvenience
}

qtConfig(vulkan): \
    SUBDIRS += vkconvenience