blob: e10a50b7c0390bd5848ad528e120901b6947ad21 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
#include "qcocoaglcontext.h"
#include "qcocoawindow.h"
#include "qcocoaautoreleasepool.h"
#include <qdebug.h>
#include <QtCore/private/qcore_mac_p.h>
#include <QtPlatformSupport/private/cglconvenience_p.h>
#import <Cocoa/Cocoa.h>
QCocoaGLContext::QCocoaGLContext(const QSurfaceFormat &format, QPlatformGLContext *share)
: m_format(format)
{
QCocoaAutoReleasePool pool; // For the SG Canvas render thread.
NSOpenGLPixelFormat *pixelFormat = static_cast <NSOpenGLPixelFormat *>(qcgl_createNSOpenGLPixelFormat());
NSOpenGLContext *actualShare = share ? static_cast<QCocoaGLContext *>(share)->m_context : 0;
m_context = [NSOpenGLContext alloc];
[m_context initWithFormat:pixelFormat shareContext:actualShare];
}
// Match up with createNSOpenGLPixelFormat!
QSurfaceFormat QCocoaGLContext::format() const
{
return m_format;
}
void QCocoaGLContext::swapBuffers(QPlatformSurface *surface)
{
QWindow *window = static_cast<QCocoaWindow *>(surface)->window();
setActiveWindow(window);
[m_context flushBuffer];
}
bool QCocoaGLContext::makeCurrent(QPlatformSurface *surface)
{
QWindow *window = static_cast<QCocoaWindow *>(surface)->window();
setActiveWindow(window);
[m_context makeCurrentContext];
return true;
}
void QCocoaGLContext::setActiveWindow(QWindow *window)
{
if (window == m_currentWindow.data())
return;
if (m_currentWindow)
static_cast<QCocoaWindow *>(m_currentWindow.data()->handle())->setCurrentContext(0);
Q_ASSERT(window->handle());
m_currentWindow = window;
QCocoaWindow *cocoaWindow = static_cast<QCocoaWindow *>(window->handle());
cocoaWindow->setCurrentContext(this);
NSView *view = cocoaWindow->windowSurfaceView();
[m_context setView:view];
}
void QCocoaGLContext::doneCurrent()
{
if (m_currentWindow)
static_cast<QCocoaWindow *>(m_currentWindow.data()->handle())->setCurrentContext(0);
m_currentWindow.clear();
[NSOpenGLContext clearCurrentContext];
}
void (*QCocoaGLContext::getProcAddress(const QByteArray &procName))()
{
return qcgl_getProcAddress(procName);
}
void QCocoaGLContext::update()
{
[m_context update];
}
NSOpenGLPixelFormat *QCocoaGLContext::createNSOpenGLPixelFormat()
{
return static_cast<NSOpenGLPixelFormat *>(qcgl_createNSOpenGLPixelFormat());
}
NSOpenGLContext *QCocoaGLContext::nsOpenGLContext() const
{
return m_context;
}
|
