summaryrefslogtreecommitdiffstats
path: root/src/plugins/platforms/directfb/directfb.pro
blob: 89d8d42ceae142019d3ba53913de0c812debc36a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
TARGET = qdirectfb

PLUGIN_TYPE = platforms
PLUGIN_CLASS_NAME = QDirectFbIntegrationPlugin
!equals(TARGET, $$QT_DEFAULT_QPA_PLUGIN): PLUGIN_EXTENDS = -
load(qt_plugin)

QT += core-private gui-private platformsupport-private

LIBS += $$QMAKE_LIBS_DIRECTFB
QMAKE_CXXFLAGS += $$QMAKE_CFLAGS_DIRECTFB

SOURCES = main.cpp \
    qdirectfbintegration.cpp \
    qdirectfbbackingstore.cpp \
    qdirectfbblitter.cpp \
    qdirectfbconvenience.cpp \
    qdirectfbinput.cpp \
    qdirectfbcursor.cpp \
    qdirectfbwindow.cpp \
    qdirectfbscreen.cpp
HEADERS = qdirectfbintegration.h \
    qdirectfbbackingstore.h \
    qdirectfbblitter.h \
    qdirectfbconvenience.h \
    qdirectfbinput.h \
    qdirectfbcursor.h \
    qdirectfbwindow.h \
    qdirectfbscreen.h \
    qdirectfbeglhooks.h

# ### port the GL context
contains(QT_CONFIG, directfb_egl) {
    HEADERS += qdirectfb_egl.h
    SOURCES += qdirectfb_egl.cpp
    DEFINES += DIRECTFB_GL_EGL
}

!isEmpty(DIRECTFB_PLATFORM_HOOKS_SOURCES) {
    HEADERS += $$DIRECTFB_PLATFORM_HOOKS_HEADERS
    SOURCES += $$DIRECTFB_PLATFORM_HOOKS_SOURCES
    DEFINES += DIRECTFB_PLATFORM_HOOKS
    LIBS += $$DIRECTFB_PLATFORM_HOOKS_LIBS
    QMAKE_LIBDIR += $$DIRECTFB_PLATFORM_HOOKS_LIBDIR
    INCLUDEPATH += $$DIRECTFB_PLATFORM_HOOKS_INCLUDEPATH
} else {
    SOURCES += qdirectfbeglhooks_stub.cpp
}


CONFIG += qpa/genericunixfontdatabase

OTHER_FILES += directfb.json