summaryrefslogtreecommitdiffstats
path: root/src/plugins/platforms/eglfs/eglfsdeviceintegration.pro
blob: 2b611f8e693e6939edfba8b439a16a1789b2728b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
# The device integration plugin base class has to live in a shared library,
# placing it into a static lib like platformsupport is not sufficient since we
# have to keep the QObject magic like qobject_cast working.
# Hence this private-only module.
# By having _p headers, it also enables developing out-of-tree integration plugins.

TARGET = QtEglFSDeviceIntegration
CONFIG += internal_module
MODULE = eglfsdeviceintegration

QT += \
    core-private gui-private \
    platformheaders-private \
    devicediscovery_support-private \
    fb_support-private

qtHaveModule(input_support-private): \
    QT += input_support-private

qtConfig(opengl): QT += opengl-private

# Avoid X11 header collision, use generic EGL native types
DEFINES += QT_EGL_NO_X11

DEFINES += QT_BUILD_EGL_DEVICE_LIB

include($$PWD/api/api.pri)

!isEmpty(EGLFS_PLATFORM_HOOKS_SOURCES) {
    HEADERS += $$EGLFS_PLATFORM_HOOKS_HEADERS
    SOURCES += $$EGLFS_PLATFORM_HOOKS_SOURCES
    LIBS    += $$EGLFS_PLATFORM_HOOKS_LIBS
    DEFINES += EGLFS_PLATFORM_HOOKS
}

!isEmpty(EGLFS_DEVICE_INTEGRATION) {
    DEFINES += EGLFS_PREFERRED_PLUGIN=$$EGLFS_DEVICE_INTEGRATION
}

CONFIG += egl

# Prevent gold linker from crashing.
# This started happening when QtPlatformSupport was modularized.
use_gold_linker: CONFIG += no_linker_version_script

!contains(DEFINES, QT_NO_CURSOR): RESOURCES += $$PWD/cursor.qrc

load(qt_module)