summaryrefslogtreecommitdiffstats
path: root/src/plugins/platforms/platforms.pro
blob: 2ce9790d9167673d171ad63449400d3c767d37ff (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
TEMPLATE = subdirs
QT_FOR_CONFIG += gui-private

android:!android-embedded: SUBDIRS += android

!wasm:!android: SUBDIRS += minimal

!wasm:!android:qtConfig(freetype): SUBDIRS += offscreen

qtConfig(xcb) {
    SUBDIRS += xcb
}

uikit:!watchos: SUBDIRS += ios
osx: SUBDIRS += cocoa

win32: SUBDIRS += windows

qtConfig(direct2d1_1):qtConfig(directwrite) {
    SUBDIRS += direct2d
}

qnx {
    SUBDIRS += qnx
}

qtConfig(eglfs) {
    SUBDIRS += eglfs
    SUBDIRS += minimalegl
}

qtConfig(directfb) {
    SUBDIRS += directfb
}

qtConfig(linuxfb): SUBDIRS += linuxfb

qtHaveModule(network):qtConfig(vnc): SUBDIRS += vnc

freebsd {
    SUBDIRS += bsdfb
}

haiku {
    SUBDIRS += haiku
}

wasm: SUBDIRS += wasm

qtConfig(integrityfb): SUBDIRS += integrity