summaryrefslogtreecommitdiffstats
path: root/src/plugins/platforms/qnx/qnx.pro
blob: fa5f69769c9d5399609c58c25cf4ae629de96703 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
TARGET = qnx

QT += platformsupport platformsupport-private

# Uncomment this to build with support for IMF once it becomes available in the BBNDK
#CONFIG += qqnx_imf

# Uncomment this to build with support for PPS based platform integration
#CONFIG += qqnx_pps

CONFIG(blackberry) {
    CONFIG += qqnx_pps

    # Unomment this to enable screen event handling
    # through a dedicated thread.
    # DEFINES += QQNX_SCREENEVENTTHREAD
} else {
    DEFINES += QQNX_SCREENEVENTTHREAD
}

# Uncomment these to enable debugging output for various aspects of the plugin
#DEFINES += QQNXBPSEVENTFILTER_DEBUG
#DEFINES += QQNXBUFFER_DEBUG
#DEFINES += QQNXBUTTON_DEBUG
#DEFINES += QQNXCLIPBOARD_DEBUG
#DEFINES += QQNXFILEDIALOGHELPER_DEBUG
#DEFINES += QQNXGLBACKINGSTORE_DEBUG
#DEFINES += QQNXGLCONTEXT_DEBUG
#DEFINES += QQNXINPUTCONTEXT_DEBUG
#DEFINES += QQNXINPUTCONTEXT_IMF_EVENT_DEBUG
#DEFINES += QQNXINTEGRATION_DEBUG
#DEFINES += QQNXNAVIGATOREVENTHANDLER_DEBUG
#DEFINES += QQNXNAVIGATOREVENTNOTIFIER_DEBUG
#DEFINES += QQNXNAVIGATOR_DEBUG
#DEFINES += QQNXRASTERBACKINGSTORE_DEBUG
#DEFINES += QQNXROOTWINDOW_DEBUG
#DEFINES += QQNXSCREENEVENTTHREAD_DEBUG
#DEFINES += QQNXSCREENEVENT_DEBUG
#DEFINES += QQNXSCREEN_DEBUG
#DEFINES += QQNXVIRTUALKEYBOARD_DEBUG
#DEFINES += QQNXWINDOW_DEBUG
#DEFINES += QQNXCURSOR_DEBUG


SOURCES =   main.cpp \
            qqnxbuffer.cpp \
            qqnxscreeneventthread.cpp \
            qqnxintegration.cpp \
            qqnxscreen.cpp \
            qqnxwindow.cpp \
            qqnxrasterbackingstore.cpp \
            qqnxrootwindow.cpp \
            qqnxscreeneventhandler.cpp \
            qqnxnativeinterface.cpp \
            qqnxnavigatoreventhandler.cpp \
            qqnxabstractnavigator.cpp \
            qqnxabstractvirtualkeyboard.cpp \
            qqnxservices.cpp \
            qqnxcursor.cpp

HEADERS =   main.h \
            qqnxbuffer.h \
            qqnxscreeneventthread.h \
            qqnxkeytranslator.h \
            qqnxintegration.h \
            qqnxscreen.h \
            qqnxwindow.h \
            qqnxrasterbackingstore.h \
            qqnxrootwindow.h \
            qqnxscreeneventhandler.h \
            qqnxnativeinterface.h \
            qqnxnavigatoreventhandler.h \
            qqnxabstractnavigator.h \
            qqnxabstractvirtualkeyboard.h \
            qqnxservices.h \
            qqnxcursor.h

LIBS += -lscreen

contains(QT_CONFIG, opengles2) {
    SOURCES += qqnxglcontext.cpp

    HEADERS += qqnxglcontext.h

    LIBS += -lEGL
}

CONFIG(blackberry) {
    SOURCES += qqnxnavigatorbps.cpp \
               qqnxeventdispatcher_blackberry.cpp \
               qqnxbpseventfilter.cpp \
               qqnxvirtualkeyboardbps.cpp \
               qqnxtheme.cpp \
               qqnxsystemsettings.cpp \
               qqnxfiledialoghelper.cpp

    HEADERS += qqnxnavigatorbps.h \
               qqnxeventdispatcher_blackberry.h \
               qqnxbpseventfilter.h \
               qqnxvirtualkeyboardbps.h  \
               qqnxtheme.h \
               qqnxsystemsettings.h \
               qqnxfiledialoghelper.h

    LIBS += -lbps
}

CONFIG(qqnx_pps) {
    DEFINES += QQNX_PPS

    SOURCES += qqnxnavigatorpps.cpp \
               qqnxnavigatoreventnotifier.cpp \
               qqnxvirtualkeyboardpps.cpp \
               qqnxclipboard.cpp \
               qqnxbuttoneventnotifier.cpp

    HEADERS += qqnxnavigatorpps.h \
               qqnxnavigatoreventnotifier.h \
               qqnxvirtualkeyboardpps.h \
               qqnxclipboard.h \
               qqnxbuttoneventnotifier.h

    LIBS += -lpps -lclipboard

    CONFIG(qqnx_imf) {
        DEFINES += QQNX_IMF
        HEADERS += qqnxinputcontext_imf.h
        SOURCES += qqnxinputcontext_imf.cpp
    } else {
        HEADERS += qqnxinputcontext_noimf.h
        SOURCES += qqnxinputcontext_noimf.cpp
    }
}

OTHER_FILES += qnx.json

QMAKE_CXXFLAGS += -I./private

include (../../../platformsupport/eglconvenience/eglconvenience.pri)
include (../../../platformsupport/fontdatabases/fontdatabases.pri)

PLUGIN_TYPE = platforms
load(qt_plugin)