summaryrefslogtreecommitdiffstats
path: root/src/widgets/styles/styles.pri
blob: b15eb1fa4852455922e07455b9219d788025e497 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
# Qt styles module

HEADERS += \
        styles/qdrawutil.h \
        styles/qstyle.h \
        styles/qstyleanimation_p.h \
        styles/qstylefactory.h \
        styles/qstyleoption.h \
        styles/qstyleplugin.h \
        styles/qcommonstylepixmaps_p.h \
        styles/qcommonstyle.h \
        styles/qstylehelper_p.h \
        styles/qproxystyle.h \
        styles/qproxystyle_p.h \
        styles/qcommonstyle_p.h \
        styles/qstylepainter.h \
        styles/qstylesheetstyle_p.h

SOURCES += \
        styles/qdrawutil.cpp \
        styles/qstyle.cpp \
        styles/qstyleanimation.cpp \
        styles/qstylefactory.cpp \
        styles/qstyleoption.cpp \
        styles/qstyleplugin.cpp \
        styles/qstylehelper.cpp \
        styles/qcommonstyle.cpp \
        styles/qproxystyle.cpp \
        styles/qstylepainter.cpp \
        styles/qstylesheetstyle.cpp \
        styles/qstylesheetstyle_default.cpp

wince* {
    RESOURCES += styles/qstyle_wince.qrc
} else {
    RESOURCES += styles/qstyle.qrc
}

contains( styles, all ) {
    styles = fusion mac windows windowsxp windowsvista
}

!macx-*|ios:styles -= mac

contains(QT_CONFIG, gtkstyle) {
    QMAKE_CXXFLAGS += $$QT_CFLAGS_QGTKSTYLE
    LIBS_PRIVATE += $$QT_LIBS_QGTKSTYLE
    styles += gtk
    CONFIG += x11
}

contains( styles, mac ) {
    HEADERS += \
        styles/qmacstyle_mac_p.h \
        styles/qmacstylepixmaps_mac_p.h \
        styles/qmacstyle_mac_p_p.h
        OBJECTIVE_SOURCES += styles/qmacstyle_mac.mm

    !contains( styles, windows ) {
        message( mac requires windows )
        styles += windows
        DEFINES+= QT_STYLE_WINDOWS
    }
} else {
    DEFINES += QT_NO_STYLE_MAC
}

contains( styles, windows ) {
    HEADERS += styles/qwindowsstyle_p.h
    HEADERS += styles/qwindowsstyle_p_p.h
    SOURCES += styles/qwindowsstyle.cpp
    DEFINES += QT_STYLE_WINDOWS
} else {
    DEFINES += QT_NO_STYLE_WINDOWS
}

contains( styles, windowsvista ) {
    HEADERS += styles/qwindowsvistastyle_p.h
    HEADERS += styles/qwindowsvistastyle_p_p.h
    SOURCES += styles/qwindowsvistastyle.cpp
    !contains( styles, windowsxp ) {
        message( windowsvista requires windowsxp )
        styles += windowsxp
        DEFINES += QT_STYLE_WINDOWSXP
    }
} else {
    DEFINES += QT_NO_STYLE_WINDOWSVISTA
}

contains( styles, windowsxp ) {
    HEADERS += styles/qwindowsxpstyle_p.h
    HEADERS += styles/qwindowsxpstyle_p_p.h
    SOURCES += styles/qwindowsxpstyle.cpp
    !contains( styles, windows ) {
        message( windowsxp requires windows )
        styles  += windows
        DEFINES += QT_STYLE_WINDOWS
    }
} else {
    DEFINES += QT_NO_STYLE_WINDOWSXP
}

contains( styles, gtk ) {
        HEADERS += styles/qgtkglobal_p.h
        HEADERS += styles/qgtkstyle_p.h
        HEADERS += styles/qgtkpainter_p.h
        HEADERS += styles/qgtk2painter_p.h
        HEADERS += styles/qgtkstyle_p_p.h
        SOURCES += styles/qgtkstyle.cpp
        SOURCES += styles/qgtkpainter.cpp
        SOURCES += styles/qgtk2painter.cpp
        SOURCES += styles/qgtkstyle_p.cpp
} else {
    DEFINES += QT_NO_STYLE_GTK
}
contains( styles, fusion ) {
        HEADERS += styles/qfusionstyle_p.h
        HEADERS += styles/qfusionstyle_p_p.h
        SOURCES += styles/qfusionstyle.cpp
} else {
    DEFINES += QT_NO_STYLE_FUSION
}

contains( styles, windowsce ) {
    HEADERS += styles/qwindowscestyle_p.h
    HEADERS += styles/qwindowscestyle_p_p.h
    SOURCES += styles/qwindowscestyle.cpp
} else {
    DEFINES += QT_NO_STYLE_WINDOWSCE
}

contains( styles, windowsmobile ) {
    HEADERS += styles/qwindowsmobilestyle_p.h
    HEADERS += styles/qwindowsmobilestyle_p_p.h
    SOURCES += styles/qwindowsmobilestyle.cpp
} else {
    DEFINES += QT_NO_STYLE_WINDOWSMOBILE
}