summaryrefslogtreecommitdiffstats
path: root/tests/auto/widgets/kernel/qapplication/test/test.pro
blob: 39b099261aa3e8db87f1e06422827c6ab8590e2d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
CONFIG += testcase

QT += widgets widgets-private testlib
QT += core-private gui-private

SOURCES += ../tst_qapplication.cpp

builtin_testdata: DEFINES += BUILTIN_TESTDATA

TESTDATA = ../test/test.pro ../tmp/README ../modal

!android: SUBPROGRAMS = desktopsettingsaware modal

debug_and_release {
    CONFIG(debug, debug|release) {
        TARGET = ../../debug/tst_qapplication
        !android: TEST_HELPER_INSTALLS = ../debug/helper
        for(file, SUBPROGRAMS): TEST_HELPER_INSTALLS += "../debug/$${file}"
    } else {
        TARGET = ../../release/tst_qapplication
        !android: TEST_HELPER_INSTALLS = ../release/helper
        for(file, SUBPROGRAMS): TEST_HELPER_INSTALLS += "../release/$${file}"
    }
} else {
    TARGET = ../tst_qapplication
    !android: TEST_HELPER_INSTALLS = ../helper
    for(file, SUBPROGRAMS): TEST_HELPER_INSTALLS += "../$${file}"
}