From a28cdb72a4ea768a898ca07f0df0fa3c17c073a8 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Tomi=20Korpip=C3=A4=C3=A4?= <tomi.korpipaa@digia.com>
Date: Tue, 10 Sep 2013 11:42:13 +0300
Subject: Module renamed

Task-number: QTRD-2224

Change-Id: Iec18b6121809300b11d85445281d3c626c434f35
Reviewed-by: Miikka Heikkinen <miikka.heikkinen@digia.com>
---
 .../datavisualizationqml2.pro                      | 54 ++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 src/datavisualizationqml2/datavisualizationqml2.pro

(limited to 'src/datavisualizationqml2/datavisualizationqml2.pro')

diff --git a/src/datavisualizationqml2/datavisualizationqml2.pro b/src/datavisualizationqml2/datavisualizationqml2.pro
new file mode 100644
index 00000000..c5ee910b
--- /dev/null
+++ b/src/datavisualizationqml2/datavisualizationqml2.pro
@@ -0,0 +1,54 @@
+TEMPLATE = lib
+TARGET = datavisualizationqml2
+QT += qml quick datavisualization
+CONFIG += qt plugin
+
+TARGET = $$qtLibraryTarget($$TARGET)
+uri = com.digia.QtDataVisualization
+
+static {
+    DEFINES += QT_DATAVISUALIZATION_STATICLIB
+    CONFIG -= static staticlib
+}
+
+# Input
+INCLUDEPATH += ../datavisualization/engine \
+               ../datavisualization/global \
+               ../datavisualization/data
+
+SOURCES += \
+    datavisualizationqml2_plugin.cpp \
+    declarativebars.cpp \
+    declarativebarsrenderer.cpp \
+    declarativescatter.cpp \
+    declarativescatterrenderer.cpp \
+    declarativesurface.cpp \
+    declarativesurfacerenderer.cpp
+
+HEADERS += \
+    datavisualizationqml2_plugin.h \
+    declarativebars_p.h \
+    declarativebarsrenderer_p.h \
+    declarativescatter_p.h \
+    declarativescatterrenderer_p.h \
+    declarativesurface_p.h \
+    declarativesurfacerenderer_p.h
+
+OTHER_FILES = qmldir
+
+!equals(_PRO_FILE_PWD_, $$OUT_PWD) {
+    copy_qmldir.target = $$OUT_PWD/qmldir
+    copy_qmldir.depends = $$_PRO_FILE_PWD_/qmldir
+    copy_qmldir.commands = $(COPY_FILE) \"$$replace(copy_qmldir.depends, /, $$QMAKE_DIR_SEP)\" \"$$replace(copy_qmldir.target, /, $$QMAKE_DIR_SEP)\"
+    QMAKE_EXTRA_TARGETS += copy_qmldir
+    PRE_TARGETDEPS += $$copy_qmldir.target
+}
+
+qmldir.files = qmldir
+unix {
+    installPath = $$[QT_INSTALL_QML]/$$replace(uri, \\., /)
+    qmldir.path = $$installPath
+    target.path = $$installPath
+    INSTALLS += target qmldir
+}
+
-- 
cgit v1.2.3