blob: aa4d7d710d03c943f5ac0e92ce8f8203cc3b48f0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
TEMPLATE = lib
TARGET = datavis3dqml2
QT += qml quick datavis3d
CONFIG += qt plugin
TARGET = $$qtLibraryTarget($$TARGET)
uri = com.digia.QtDataVis3D
static {
DEFINES += QT_DATAVIS3D_STATICLIB
CONFIG -= static staticlib
}
# Input
INCLUDEPATH += ../datavis3d/engine \
../datavis3d/global \
../datavis3d/data
SOURCES += \
datavis3dqml2_plugin.cpp \
declarativebars.cpp \
declarativebarsrenderer.cpp \
declarativescatter.cpp \
declarativescatterrenderer.cpp \
declarativesurface.cpp \
declarativesurfacerenderer.cpp
HEADERS += \
datavis3dqml2_plugin.h \
declarativebars_p.h \
declarativebarsrenderer_p.h \
declarativescatter_p.h \
declarativescatterrenderer_p.h \
declarativesurface_p.h \
declarativesurfacerenderer_p.h
OTHER_FILES = qmldir
!equals(_PRO_FILE_PWD_, $$OUT_PWD) {
copy_qmldir.target = $$OUT_PWD/qmldir
copy_qmldir.depends = $$_PRO_FILE_PWD_/qmldir
copy_qmldir.commands = $(COPY_FILE) \"$$replace(copy_qmldir.depends, /, $$QMAKE_DIR_SEP)\" \"$$replace(copy_qmldir.target, /, $$QMAKE_DIR_SEP)\"
QMAKE_EXTRA_TARGETS += copy_qmldir
PRE_TARGETDEPS += $$copy_qmldir.target
}
qmldir.files = qmldir
unix {
installPath = $$[QT_INSTALL_QML]/$$replace(uri, \\., /)
qmldir.path = $$installPath
target.path = $$installPath
INSTALLS += target qmldir
}
|
