blob: 87376e709bfe70f3e90efe2493fa015d787f6866 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
TARGET = datavisualizationqml2
QT += qml quick datavisualization
osx: QT += gui-private
TARGETPATH = QtDataVisualization
IMPORT_VERSION = $$MODULE_VERSION
# Only build qml plugin static if Qt itself is also built static
!contains(QT_CONFIG, static): CONFIG -= static staticlib
include($$PWD/designer/designer.pri)
INCLUDEPATH += ../../include \
../../include/QtDataVisualization \
../datavisualization/engine \
../datavisualization/global \
../datavisualization/data \
../datavisualization/theme
SOURCES += \
datavisualizationqml2_plugin.cpp \
declarativebars.cpp \
declarativescatter.cpp \
declarativesurface.cpp \
abstractdeclarative.cpp \
colorgradient.cpp \
declarativeseries.cpp \
declarativetheme.cpp \
declarativecolor.cpp \
declarativescene.cpp \
declarativerendernode.cpp \
glstatestore.cpp \
enumtostringmap.cpp
HEADERS += \
datavisualizationqml2_plugin.h \
declarativebars_p.h \
declarativescatter_p.h \
declarativesurface_p.h \
abstractdeclarative_p.h \
colorgradient_p.h \
declarativeseries_p.h \
declarativetheme_p.h \
declarativecolor_p.h \
declarativescene_p.h \
declarativerendernode_p.h \
glstatestore_p.h \
enumtostringmap_p.h
OTHER_FILES = qmldir
CONFIG += no_cxx_module
load(qml_plugin)
# Copy qmldir to DESTDIR so we can use the plugin directly from there in our examples
# without having to do 'make install'.
!android:!ios {
copy_qmldir.target = $$DESTDIR/qmldir
copy_qmldir.depends = $$_PRO_FILE_PWD_/qmldir
copy_qmldir.commands = $(COPY_FILE) \"$$replace(copy_qmldir.depends, /, $$QMAKE_DIR_SEP)\" \"$$replace(copy_qmldir.target, /, $$QMAKE_DIR_SEP)\"
QMAKE_EXTRA_TARGETS += copy_qmldir
PRE_TARGETDEPS += $$copy_qmldir.target
}
QML_FILES += \
$$PWD/plugins.qmltypes
|
