summaryrefslogtreecommitdiffstats
path: root/tools/generate_package_win.cmd
blob: f3647c492a50eb5d9cbc6dafb5eb310c84bf041d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
@echo off

SETLOCAL

set DATAVIS_TEMP_DIR=temp_dir
set DATAVIS_TEMP_DIR_FULL=..\%DATAVIS_TEMP_DIR%

if "%1"=="" (
    echo Usage: generate_package_win version [branch or SHA]
    echo Branch defaults to master.
    echo Creates the package in parent dir.
    echo A temporary dir %DATAVIS_TEMP_DIR_FULL% is utilized for intermediate steps.
    goto :end
)

if "%2"=="" (
    set DATAVIS_BRANCH=origin/master
) else (
    set DATAVIS_BRANCH=%2
)

set DATAVIS_VERSION=%1
set DATAVIS_PACKAGE_NAME=qt-data-visualization-enterprise-src-%DATAVIS_VERSION%
set DATAVIS_BUILD_DIR=%DATAVIS_TEMP_DIR_FULL%\tempbuild
set DATAVIS_PACKAGE_UNZIP_DIR=%DATAVIS_TEMP_DIR_FULL%\%DATAVIS_PACKAGE_NAME%
set DATAVIS_TEMP_ZIP=qtdatavisualization_temp_%DATAVIS_VERSION%.zip
set DATAVIS_TEMP_ZIP_FULL=%DATAVIS_TEMP_DIR_FULL%\%DATAVIS_TEMP_ZIP%
set DATAVIS_XCOPY_CMD=xcopy /s /i /q
set DATAVIS_FINAL_ZIP=..\%DATAVIS_PACKAGE_NAME%.zip

echo Exporting %DATAVIS_BRANCH% to %DATAVIS_TEMP_ZIP_FULL%...
rmdir /q /s %DATAVIS_TEMP_DIR_FULL% 2> NUL
md %DATAVIS_TEMP_DIR_FULL% 2> NUL
call git fetch
call git archive --format zip --output ../%DATAVIS_TEMP_DIR%/%DATAVIS_TEMP_ZIP% %DATAVIS_BRANCH%

echo Unzipping %DATAVIS_TEMP_ZIP_FULL% to %DATAVIS_PACKAGE_UNZIP_DIR% and %DATAVIS_BUILD_DIR%...
md %DATAVIS_PACKAGE_UNZIP_DIR% 2> NUL
md %DATAVIS_BUILD_DIR% 2> NUL
call 7z x -y -o%DATAVIS_PACKAGE_UNZIP_DIR% %DATAVIS_TEMP_ZIP_FULL%  > NUL
call 7z x -y -o%DATAVIS_BUILD_DIR% %DATAVIS_TEMP_ZIP_FULL%  > NUL
::Workaround for git archive bug
rmdir /q /s %DATAVIS_PACKAGE_UNZIP_DIR%\tests 2> NUL
rmdir /q /s %DATAVIS_PACKAGE_UNZIP_DIR%\tools 2> NUL
rmdir /q /s %DATAVIS_BUILD_DIR%\tests 2> NUL
rmdir /q /s %DATAVIS_BUILD_DIR%\tools 2> NUL

echo Generating includes, mkspecs, and docs in %DATAVIS_BUILD_DIR%...
pushd %DATAVIS_BUILD_DIR%
::Fake git build to get syncqt to run
md .git 2> NUL
qmake > NUL 2> NUL
nmake docs > NUL 2> NUL
popd

echo Copying generated files to %DATAVIS_PACKAGE_UNZIP_DIR%
%DATAVIS_XCOPY_CMD% %DATAVIS_BUILD_DIR%\doc %DATAVIS_PACKAGE_UNZIP_DIR%\doc
%DATAVIS_XCOPY_CMD% %DATAVIS_BUILD_DIR%\include %DATAVIS_PACKAGE_UNZIP_DIR%\include

echo Repackaging %DATAVIS_PACKAGE_UNZIP_DIR% to %DATAVIS_FINAL_ZIP%
del /q %DATAVIS_FINAL_ZIP% 2> NUL
call 7z a -r -y -tzip %DATAVIS_FINAL_ZIP% %DATAVIS_PACKAGE_UNZIP_DIR% >NUL

:end