Start of examples refactor

This is the general reorg of the examples directory structure, plus additional
guidelines.

calculator, animations and accessibility have been updated to the new standards
and tested, as an example.

Task-number: QTBUG-24133
Change-Id: I76c3b86751d3195ba2a5474ff23afb875765e9a4
Reviewed-by: Alan Alpert <alan.alpert@nokia.com>

1 files changed, 140 insertions, 0 deletions

diff --git a/examples/demos/snake/content/HighScoreModel.qml b/examples/demos/snake/content/HighScoreModel.qml
new file mode 100644
index 0000000000..af66b99ede
--- /dev/null
+++ b/examples/demos/snake/content/HighScoreModel.qml
@@ -0,0 +1,140 @@
+/****************************************************************************
+**
+** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
+** Contact: http://www.qt-project.org/
+**
+** This file is part of the QtDeclarative module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** GNU Lesser General Public License Usage
+** This file may be used under the terms of the GNU Lesser General Public
+** License version 2.1 as published by the Free Software Foundation and
+** appearing in the file LICENSE.LGPL included in the packaging of this
+** file. Please review the following information to ensure the GNU Lesser
+** General Public License version 2.1 requirements will be met:
+** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
+**
+** In addition, as a special exception, Nokia gives you certain additional
+** rights. These rights are described in the Nokia Qt LGPL Exception
+** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU General
+** Public License version 3.0 as published by the Free Software Foundation
+** and appearing in the file LICENSE.GPL included in the packaging of this
+** file. Please review the following information to ensure the GNU General
+** Public License version 3.0 requirements will be met:
+** http://www.gnu.org/copyleft/gpl.html.
+**
+** Other Usage
+** Alternatively, this file may be used in accordance with the terms and
+** conditions contained in a signed written agreement between you and Nokia.
+**
+**
+**
+**
+**
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.0
+import QtQuick.LocalStorage 2.0 as Sql
+
+// Models a high score table.
+//
+// Use this component like this:
+//
+//  HighScoreModel {
+//      id: highScores
+//      game: "MyCoolGame"
+//  }
+//
+// Then use either use the top-score properties:
+//
+//  Text { text: "HI: " + highScores.topScore }
+//
+// or, use the model in a view:
+//
+//  ListView {
+//      model: highScore
+//      delegate: Component {
+//                    ... player ... score ...
+//                }
+//  }
+//
+// Add new scores via:
+//
+//  saveScore(newScore)
+//
+// or:
+//
+//  savePlayerScore(playerName,newScore)
+//
+// The best maxScore scores added by this method will be retained in an SQL database,
+// and presented in the model and in the topScore/topPlayer properties.
+//
+
+ListModel {
+    id: model
+    property string game: ""
+    property int topScore: 0
+    property string topPlayer: ""
+    property int maxScores: 10
+
+    function __db()
+    {
+        return Sql.openDatabaseSync("HighScoreModel", "1.0", "Generic High Score Functionality for QML", 1000000);
+    }
+    function __ensureTables(tx)
+    {
+        tx.executeSql('CREATE TABLE IF NOT EXISTS HighScores(game TEXT, score INT, player TEXT)', []);
+    }
+
+    function fillModel() {
+        __db().transaction(
+            function(tx) {
+                __ensureTables(tx);
+                var rs = tx.executeSql("SELECT score,player FROM HighScores WHERE game=? ORDER BY score DESC", [game]);
+                model.clear();
+                if (rs.rows.length > 0) {
+                    topScore = rs.rows.item(0).score
+                    topPlayer = rs.rows.item(0).player
+                    for (var i=0; i<rs.rows.length; ++i) {
+                        if (i < maxScores)
+                            model.append(rs.rows.item(i))
+                    }
+                    if (rs.rows.length > maxScores)
+                        tx.executeSql("DELETE FROM HighScores WHERE game=? AND score <= ?",
+                                            [game, rs.rows.item(maxScores).score]);
+                }
+            }
+        )
+    }
+
+    function savePlayerScore(player,score) {
+        __db().transaction(
+            function(tx) {
+                __ensureTables(tx);
+                tx.executeSql("INSERT INTO HighScores VALUES(?,?,?)", [game,score,player]);
+                fillModel();
+            }
+        )
+    }
+
+    function saveScore(score) {
+        savePlayerScore("player",score);
+    }
+
+    function clearScores() {
+        __db().transaction(
+            function(tx) {
+                tx.executeSql("DELETE FROM HighScores WHERE game=?", [game]);
+                fillModel();
+            }
+        )
+    }
+
+    Component.onCompleted: { fillModel() }
+}