Move most of the pointer manual tests to a new pointerhandlers example

They were always meant to be examples eventually. Now they will be used
for an example of how to implement custom controls using only basic
items and handlers. Some components are very similar to those in
the shared directory; but most examples will use Qt Quick Controls,
so those shared components can be removed when we no longer use them.
This example should remain as the one that shows how to build
reusable controls "from scratch".

Removed InputInspector because it's inefficient, has limited usefulness,
tends to require building the manual test to be able to run it, and
could be better built as a reusable Qt.labs component later on,
providing a model with all known devices and taking advantage of the
QPointingDevice::grabChanged signal to track the grab states rather
than polling.

Change-Id: I47ab6ebb2cecab07a69cf96e546ffd0db3026a60
Reviewed-by: Fabian Kosmale <fabian.kosmale@qt.io>
Reviewed-by: Oliver Eftevaag <oliver.eftevaag@qt.io>
Reviewed-by: Shawn Rutledge <shawn.rutledge@qt.io>
(cherry picked from commit 8503f884bbdb50c4bebc8f8a9fce05275b0612b1)

17 files changed, 1106 insertions, 0 deletions

diff --git a/examples/quick/pointerhandlers/components/Button.qml b/examples/quick/pointerhandlers/components/Button.qml
new file mode 100644
index 0000000000..9ff3870d7b
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/Button.qml
@@ -0,0 +1,105 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick
+
+Rectangle {
+    id: root
+    property alias label: label
+    property alias text: label.text
+    property alias pressed: tap.pressed
+    property alias hovered: hoverHandler.hovered
+    property alias gesturePolicy: tap.gesturePolicy
+    property alias margin: tap.margin
+    signal tapped
+
+    implicitHeight: Math.max(Screen.pixelDensity * 7, label.implicitHeight * 2)
+    implicitWidth: Math.max(Screen.pixelDensity * 11, label.implicitWidth * 1.3)
+    height: implicitHeight
+    width: implicitWidth
+    radius: height / 6
+
+    border { color: Qt.darker(palette.button, 1.5); width: 1 }
+    gradient: Gradient {
+            GradientStop { position: 0.0; color: tap.pressed ? Qt.darker(palette.button, 1.3) : palette.button }
+            GradientStop { position: 1.0; color: Qt.darker(palette.button, 1.3) }
+    }
+
+    TapHandler {
+        id: tap
+        margin: 10 // the user can tap a little beyond the edges
+        objectName: label.text + " Tap"
+        onTapped: {
+            tapFlash.start()
+            root.tapped()
+        }
+    }
+    HoverHandler {
+        id: hoverHandler
+    }
+
+    Text {
+        id: label
+        font.pointSize: 14
+        color: palette.buttonText
+        text: "Button"
+        anchors.centerIn: parent
+    }
+
+    Rectangle {
+        anchors.fill: parent
+        color: "transparent"
+        border.width: 2; radius: root.radius; antialiasing: true
+        opacity: tapFlash.running ? 1 : 0
+        FlashAnimation on visible {
+            id: tapFlash
+        }
+    }
+}
diff --git a/examples/quick/pointerhandlers/components/CheckBox.qml b/examples/quick/pointerhandlers/components/CheckBox.qml
new file mode 100644
index 0000000000..bcd9ad99db
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/CheckBox.qml
@@ -0,0 +1,105 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick
+
+Item {
+    id: root
+    implicitHeight: frame.height
+    implicitWidth: row.implicitWidth
+    width: implicitWidth
+    height: implicitHeight
+    property alias text: label.text
+    property bool checked
+
+    property alias pressed: tapHandler.pressed
+    property alias row: row
+    signal clicked
+
+    Row {
+        id: row
+        anchors.verticalCenter: parent.verticalCenter
+        spacing: 6
+        Rectangle {
+            id: frame
+            gradient: Gradient {
+                GradientStop { position: 0.0; color: tapHandler.pressed ? Qt.darker(palette.button, 1.3) : palette.button }
+                GradientStop { position: 1.0; color: Qt.darker(palette.button, 1.3) }
+            }
+            height: label.implicitHeight * 1.5
+            width: height
+            anchors.margins: 1
+            radius: 3
+            antialiasing: true
+            border.color: Qt.darker(palette.button, 1.5)
+            Image {
+                id: theX
+                source: "images/checkmark.png"
+                anchors.fill: frame
+                anchors.margins: frame.width / 5
+                fillMode: Image.PreserveAspectFit
+                smooth: true
+                visible: root.checked
+            }
+        }
+        Text {
+            id: label
+            color: palette.text
+            anchors.verticalCenter: frame.verticalCenter
+        }
+    }
+    TapHandler {
+        id: tapHandler
+        onTapped: {
+            parent.checked = !parent.checked
+            parent.clicked()
+        }
+    }
+}
diff --git a/examples/quick/pointerhandlers/components/FakeFlickable.qml b/examples/quick/pointerhandlers/components/FakeFlickable.qml
new file mode 100644
index 0000000000..2857d066aa
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/FakeFlickable.qml
@@ -0,0 +1,149 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.14
+import Qt.labs.animation 1.0
+
+Item {
+    id: root
+    objectName: "viewport"
+    default property alias data: __contentItem.data
+    property alias velocity: anim.velocity
+    property alias contentX: __contentItem.x // sign is reversed compared to Flickable.contentX
+    property alias contentY: __contentItem.y // sign is reversed compared to Flickable.contentY
+    property alias contentWidth: __contentItem.width
+    property alias contentHeight: __contentItem.height
+    signal flickStarted
+    signal flickEnded
+
+    Item {
+        id: __contentItem
+        objectName: "__contentItem"
+        width: childrenRect.width
+        height: childrenRect.height
+
+        BoundaryRule on x {
+            id: xbr
+            minimum: root.width - __contentItem.width
+            maximum: 0
+            minimumOvershoot: 100
+            maximumOvershoot: 100
+            overshootFilter: BoundaryRule.Peak
+        }
+
+        BoundaryRule on y {
+            id: ybr
+            minimum: root.height - __contentItem.height
+            maximum: 0
+            minimumOvershoot: 100
+            maximumOvershoot: 100
+            overshootFilter: BoundaryRule.Peak
+        }
+
+        DragHandler {
+            id: dragHandler
+            onActiveChanged:
+                if (active) {
+                    anim.stop()
+                    root.flickStarted()
+                } else {
+                    var vel = centroid.velocity
+                    if (xbr.returnToBounds())
+                        vel.x = 0
+                    if (ybr.returnToBounds())
+                        vel.y = 0
+                    if (vel.x !== 0 || vel.y !== 0)
+                        anim.restart(vel)
+                    else
+                        root.flickEnded()
+                }
+        }
+        WheelHandler {
+            rotationScale: 15
+            property: "x"
+            orientation: Qt.Horizontal
+            acceptedDevices: PointerDevice.Mouse | PointerDevice.TouchPad
+            onActiveChanged:
+                // emitting signals in both instances is redundant but hard to avoid
+                // when the touchpad is flicking along both axes
+                if (active) {
+                    anim.stop()
+                    root.flickStarted()
+                } else {
+                    xbr.returnToBounds()
+                    root.flickEnded()
+                }
+        }
+        WheelHandler {
+            rotationScale: 15
+            property: "y"
+            orientation: Qt.Vertical
+            acceptedDevices: PointerDevice.Mouse | PointerDevice.TouchPad
+            onActiveChanged:
+                if (active) {
+                    anim.stop()
+                    root.flickStarted()
+                } else {
+                    ybr.returnToBounds()
+                    root.flickEnded()
+                }
+        }
+        MomentumAnimation {
+            id: anim
+            target: __contentItem
+            onStarted: root.flickStarted()
+            onStopped: {
+                xbr.returnToBounds()
+                ybr.returnToBounds()
+                root.flickEnded()
+            }
+        }
+    }
+}
diff --git a/examples/quick/pointerhandlers/components/FlashAnimation.qml b/examples/quick/pointerhandlers/components/FlashAnimation.qml
new file mode 100644
index 0000000000..047112d22c
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/FlashAnimation.qml
@@ -0,0 +1,67 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.12
+
+SequentialAnimation {
+    id: tapFlash
+    running: false
+    PropertyAction { value: false }
+    PauseAnimation { duration: 100 }
+    PropertyAction { value: true }
+    PauseAnimation { duration: 100 }
+    PropertyAction { value: false }
+    PauseAnimation { duration: 100 }
+    PropertyAction { value: true }
+    PauseAnimation { duration: 100 }
+    PropertyAction { value: false }
+    PauseAnimation { duration: 100 }
+    PropertyAction { value: true }
+}
diff --git a/examples/quick/pointerhandlers/components/LeftDrawer.qml b/examples/quick/pointerhandlers/components/LeftDrawer.qml
new file mode 100644
index 0000000000..5cf1420519
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/LeftDrawer.qml
@@ -0,0 +1,123 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+import QtQuick
+import Qt.labs.animation
+
+Item {
+    id: root
+    objectName: "LeftHandlerDrawer"
+    width: 100
+    height: 400
+    property real stickout: 4
+    property real xOpen: rect.radius * -2
+    property real xClosed: stickout - width
+    x: xClosed
+    y: 10
+
+    function close() {
+        openCloseAnimation.to = xClosed
+        openCloseAnimation.start()
+    }
+    function open() {
+        openCloseAnimation.to = xOpen
+        openCloseAnimation.start()
+    }
+
+    DragHandler {
+        id: dragHandler
+        yAxis.enabled: false
+        xAxis.minimum: -1000
+        margin: 20
+        onActiveChanged:
+            if (!active) {
+                if (xbr.returnToBounds())
+                    return;
+                if (activeTranslation.x > 0)
+                    open()
+                if (activeTranslation.x < 0)
+                    close()
+            }
+    }
+
+    BoundaryRule on x {
+        id: xbr
+        minimum: xClosed
+        maximum: xOpen
+        minimumOvershoot: rect.radius
+        maximumOvershoot: rect.radius
+    }
+
+    NumberAnimation on x {
+        id: openCloseAnimation
+        duration: 300
+        easing { type: Easing.OutBounce; overshoot: 5 }
+    }
+
+    // TODO this was supposed to be RectangularGlow but we lost QtGraphicalEffects in Qt 6
+    Rectangle {
+        id: effect
+        anchors.fill: parent
+        border.width: dragHandler.margin
+        border.color: "cyan"
+        opacity: 0.2
+        radius: rect.radius + dragHandler.margin
+    }
+
+    Rectangle {
+        id: rect
+        anchors.fill: parent
+        anchors.margins: 3
+        color: "#333"
+        border.color: "cyan"
+        border.width: 2
+        radius: 10
+        antialiasing: true
+    }
+}
diff --git a/examples/quick/pointerhandlers/components/MomentumAnimation.qml b/examples/quick/pointerhandlers/components/MomentumAnimation.qml
new file mode 100644
index 0000000000..03e1689317
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/MomentumAnimation.qml
@@ -0,0 +1,81 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.12
+
+ParallelAnimation {
+    id: root
+    property Item target: null
+    property int duration: 500
+    property vector2d velocity: Qt.vector2d(0,0)
+
+    function restart(vel) {
+        stop()
+        velocity = vel
+        start()
+    }
+
+    NumberAnimation {
+        id: xAnim
+        target: root.target
+        property: "x"
+        to: target.x + velocity.x / duration * 100
+        duration: root.duration
+        easing.type: Easing.OutQuad
+    }
+    NumberAnimation {
+        id: yAnim
+        target: root.target
+        property: "y"
+        to: target.y + velocity.y / duration * 100
+        duration: root.duration
+        easing.type: Easing.OutQuad
+    }
+}
diff --git a/examples/quick/pointerhandlers/components/MouseFeedbackSprite.qml b/examples/quick/pointerhandlers/components/MouseFeedbackSprite.qml
new file mode 100644
index 0000000000..4d6f1843c8
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/MouseFeedbackSprite.qml
@@ -0,0 +1,78 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.12
+
+PointHandler {
+    id: handler
+    objectName: "mouse point"
+    acceptedDevices: PointerDevice.Mouse
+    acceptedButtons: Qt.AllButtons
+    target: Image {
+        objectName: "mouse sprite"
+        source: "images/mouse.png"
+        visible: handler.active
+        x: handler.point.position.x - width / 2
+        y: handler.point.position.y - height / 2
+        parent: handler.parent
+        Image {
+            source: "images/mouse_left.png"
+            visible: handler.point.pressedButtons & Qt.LeftButton
+        }
+        Image {
+            source: "images/mouse_middle.png"
+            visible: handler.point.pressedButtons & Qt.MiddleButton
+        }
+        Image {
+            source: "images/mouse_right.png"
+            visible: handler.point.pressedButtons & Qt.RightButton
+        }
+    }
+}
diff --git a/examples/quick/pointerhandlers/components/ScrollBar.qml b/examples/quick/pointerhandlers/components/ScrollBar.qml
new file mode 100644
index 0000000000..f5cf27a0c5
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/ScrollBar.qml
@@ -0,0 +1,167 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.12
+
+Rectangle {
+    id: root
+    property real contentHeight: 100
+    property FakeFlickable flick: null
+    property real position
+
+    onPositionChanged: if (flick && (drag.active || tap.active)) {
+        if (knob.state === "horizontal")
+            flick.contentX = position * knob.scrollDistance
+        else if (knob.state === "vertical")
+            flick.contentY = position * knob.scrollDistance
+    }
+
+    color: palette.button
+    border.color: Qt.darker(palette.button, 1.5)
+    gradient: Gradient {
+        GradientStop { position: 0; color: Qt.darker(palette.button, 1.3) }
+        GradientStop { position: 1; color: palette.button }
+    }
+    antialiasing: true
+    radius: Math.min(width, height) / 6
+    width: 20
+    height: 20
+
+    TapHandler {
+        id: tap
+        onTapped: {
+            if (knob.state === "horizontal")
+                knob.x = position.x - knob.width / 2
+            else if (knob.state === "vertical")
+                knob.y = position.y - knob.height / 2
+        }
+    }
+
+    Rectangle {
+        id: knob
+        border.color: "black"
+        border.width: 1
+        gradient: Gradient {
+            GradientStop { position: 0; color: palette.button }
+            GradientStop { position: 1; color: Qt.darker(palette.button, 1.3) }
+        }
+        radius: 2
+        antialiasing: true
+        state: root.height > root.width ? "vertical" : root.height < root.width ? "horizontal" : ""
+        property real scrollDistance: 0
+        property real scrolledX: 0
+        property real scrolledY: 0
+        property real max: 0
+
+        Binding on x {
+            value: knob.scrolledX
+            when: !drag.active
+        }
+
+        Binding on y {
+            value: knob.scrolledY
+            when: !drag.active
+        }
+
+        states: [
+            // We will control the horizontal. We will control the vertical.
+            State {
+                name: "horizontal"
+                PropertyChanges {
+                    target: knob
+                    max: root.width - knob.width
+                    scrolledX: Math.min(max, Math.max(0, max * flick.contentX / (flick.width - flick.contentWidth)))
+                    scrolledY: 1
+                    scrollDistance: flick.width - flick.contentWidth
+                    width: flick.width * (flick.width / flick.contentWidth) - (height - anchors.margins) * 2
+                    height: root.height - 2
+                }
+                PropertyChanges {
+                    target: drag
+                    xAxis.minimum: 0
+                    xAxis.maximum: knob.max
+                    yAxis.minimum: 1
+                    yAxis.maximum: 1
+                }
+                PropertyChanges {
+                    target: root
+                    position: knob.x / drag.xAxis.maximum
+                }
+            },
+            State {
+                name: "vertical"
+                PropertyChanges {
+                    target: knob
+                    max: root.height - knob.height
+                    scrolledX: 1
+                    scrolledY: Math.min(max, Math.max(0, max * flick.contentY / (flick.height - flick.contentHeight)))
+                    scrollDistance: flick.height - flick.contentHeight
+                    width: root.width - 2
+                    height: root.width - 2
+                }
+                PropertyChanges {
+                    target: drag
+                    xAxis.minimum: 1
+                    xAxis.maximum: 1
+                    yAxis.minimum: 0
+                    yAxis.maximum: knob.max
+                }
+                PropertyChanges {
+                    target: root
+                    position: knob.y / drag.yAxis.maximum
+                }
+            }
+        ]
+
+        DragHandler {
+            id: drag
+        }
+    }
+}
diff --git a/examples/quick/pointerhandlers/components/Slider.qml b/examples/quick/pointerhandlers/components/Slider.qml
new file mode 100644
index 0000000000..0365d01149
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/Slider.qml
@@ -0,0 +1,159 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick
+import Qt.labs.animation
+
+Item {
+    id: root
+    property int value: 50
+    property int maximumValue: 99
+    property alias label: label.text
+    property alias tapEnabled: tap.enabled
+    property alias pressed: tap.pressed
+    signal tapped
+
+    DragHandler {
+        id: dragHandler
+        objectName: label.text + " DragHandler"
+        target: knob
+        xAxis.enabled: false
+    }
+
+    WheelHandler {
+        id: wheelHandler
+        objectName: label.text + " WheelHandler"
+        acceptedDevices: PointerDevice.Mouse | PointerDevice.TouchPad
+        invertible: false   // Don't let the system "natural scrolling" setting affect this
+        rotationScale: -0.5 // But make it go consistently in the same direction as the fingers or wheel, a bit slow
+        target: knob
+        property: "y"
+    }
+
+    Rectangle {
+        id: slot
+        anchors.top: parent.top
+        anchors.bottom: parent.bottom
+        anchors.margins: 10
+        anchors.topMargin: label.height + 6
+        anchors.bottomMargin: valueLabel.height + 4
+        anchors.horizontalCenter: parent.horizontalCenter
+        width: 10
+        color: "black"
+        radius: width / 2
+        smooth: true
+    }
+
+    Rectangle {
+        // RectangularGlow is better, but that's a different module
+        id: glow
+        anchors.fill: knob
+        anchors.margins: -5
+        anchors.leftMargin: -2
+        anchors.horizontalCenterOffset: 1
+        radius: 5
+        color: "#4400FFFF"
+        opacity: tap.pressed || tapFlash.running ? 1 : 0
+        FlashAnimation on visible {
+            id: tapFlash
+        }
+    }
+    Image {
+        id: knob
+        source: "images/mixer-knob.png"
+        antialiasing: true
+        x: slot.x - width / 2 + slot.width / 2
+        height: root.width / 2
+        width: implicitWidth / implicitHeight * height
+        property bool programmatic: false
+        property real multiplier: root.maximumValue / (ybr.maximum - ybr.minimum)
+        onYChanged: if (!programmatic) root.value = root.maximumValue - (knob.y - ybr.minimum) * multiplier
+        transformOrigin: Item.Center
+        function setValue(value) { knob.y = ybr.maximum - value / knob.multiplier }
+        TapHandler {
+            id: tap
+            objectName: label.text + " TapHandler"
+            gesturePolicy: TapHandler.DragThreshold
+            onTapped: {
+                tapFlash.start()
+                root.tapped
+            }
+        }
+        BoundaryRule on y {
+            id: ybr
+            minimum: slot.y
+            maximum: slot.height + slot.y - knob.height
+        }
+    }
+
+    Text {
+        id: valueLabel
+        font.pointSize: 16
+        color: "red"
+        anchors.bottom: parent.bottom
+        anchors.horizontalCenter: parent.horizontalCenter
+        text: root.value
+    }
+
+    Text {
+        id: label
+        font.pointSize: 12
+        color: "red"
+        anchors.top: parent.top
+        anchors.topMargin: 5
+        anchors.horizontalCenter: parent.horizontalCenter
+    }
+
+    onHeightChanged: {
+        knob.programmatic = true
+        knob.setValue(root.value)
+        knob.programmatic = false
+    }
+}
diff --git a/examples/quick/pointerhandlers/components/TouchpointFeedbackSprite.qml b/examples/quick/pointerhandlers/components/TouchpointFeedbackSprite.qml
new file mode 100644
index 0000000000..5a4f258b8c
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/TouchpointFeedbackSprite.qml
@@ -0,0 +1,72 @@
+/****************************************************************************
+**
+** Copyright (C) 2021 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.12
+
+PointHandler {
+    id: handler
+    objectName: "point " + handler.point.id.toString(16)
+    acceptedDevices: PointerDevice.TouchScreen | PointerDevice.TouchPad
+    target: AnimatedSprite {
+        objectName: "sprite " + handler.point.id.toString(16)
+        source: "images/fingersprite.png"
+        visible: handler.active
+        running: visible // QTBUG-64544: running defaults to true, but we don't see it animating if we don't toggle it like this
+        x: handler.point.position.x - 20
+        y: handler.point.position.y - 13
+        width: frameWidth
+        height: frameHeight
+        frameWidth: 43
+        frameHeight: 64
+        frameCount: 3
+        frameRate: 5
+        parent: handler.parent
+    }
+}
diff --git a/examples/quick/pointerhandlers/components/images/checkmark.png b/examples/quick/pointerhandlers/components/images/checkmark.png
new file mode 100644
index 0000000000..821aafccdd
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/images/checkmark.png
diff --git a/examples/quick/pointerhandlers/components/images/fingersprite.png b/examples/quick/pointerhandlers/components/images/fingersprite.png
new file mode 100644
index 0000000000..423d115fdf
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/images/fingersprite.png
diff --git a/examples/quick/pointerhandlers/components/images/mixer-knob.png b/examples/quick/pointerhandlers/components/images/mixer-knob.png
new file mode 100644
index 0000000000..b7d42ee3bd
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/images/mixer-knob.png
diff --git a/examples/quick/pointerhandlers/components/images/mouse.png b/examples/quick/pointerhandlers/components/images/mouse.png
new file mode 100644
index 0000000000..268946df0a
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/images/mouse.png
diff --git a/examples/quick/pointerhandlers/components/images/mouse_left.png b/examples/quick/pointerhandlers/components/images/mouse_left.png
new file mode 100644
index 0000000000..9292301b47
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/images/mouse_left.png
diff --git a/examples/quick/pointerhandlers/components/images/mouse_middle.png b/examples/quick/pointerhandlers/components/images/mouse_middle.png
new file mode 100644
index 0000000000..064e8b9c16
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/images/mouse_middle.png
diff --git a/examples/quick/pointerhandlers/components/images/mouse_right.png b/examples/quick/pointerhandlers/components/images/mouse_right.png
new file mode 100644
index 0000000000..cab1a36ba6
--- /dev/null
+++ b/examples/quick/pointerhandlers/components/images/mouse_right.png