Remove "2" from Qt Quick Controls directories

Qt Quick Controls 2 was named that way because it was a follow-up to
Qt Quick Controls 1.x. Now that Qt Quick Controls 1 is no longer
supported, we don't need to have "2" in the name. Work on this was
already started for the documentation in
1abdfe5d5a052f2298b7bf657513dfa7e0c66a56.

By doing this renaming a few weeks before feature freeze, it won't
affect the release but still results in as little time possible spent
manually fixing conflicts in cherry-picks from non-LTS releases as a
result of the renaming.

This patch does the following:

- Renames directories.
- Adapts CMakeLists.txt and other files to account for the new paths.

A follow-up patch will handle documentation.

It does not touch library names or other user-facing stuff, as that
will have to be done in Qt 7.

Task-number: QTBUG-95413
Change-Id: I170d8db19033ee71e495ff0c5c1a517a41ed7634
Reviewed-by: Mitch Curtis <mitch.curtis@qt.io>

1 files changed, 136 insertions, 0 deletions

diff --git a/src/quickdialogs/quickdialogsquickimpl/qml/+Fusion/FolderDialog.qml b/src/quickdialogs/quickdialogsquickimpl/qml/+Fusion/FolderDialog.qml
new file mode 100644
index 0000000000..fbe0fa9c19
--- /dev/null
+++ b/src/quickdialogs/quickdialogsquickimpl/qml/+Fusion/FolderDialog.qml
@@ -0,0 +1,136 @@
+// Copyright (C) 2021 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+import Qt.labs.folderlistmodel
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Controls.impl
+import QtQuick.Controls.Fusion
+import QtQuick.Controls.Fusion.impl
+import QtQuick.Dialogs
+import QtQuick.Dialogs.quickimpl
+import QtQuick.Layouts
+import QtQuick.Templates as T
+
+import "." as DialogsImpl
+
+FolderDialogImpl {
+    id: control
+
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            contentWidth + leftPadding + rightPadding,
+                            implicitHeaderWidth,
+                            implicitFooterWidth)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             contentHeight + topPadding + bottomPadding
+                             + (implicitHeaderHeight > 0 ? implicitHeaderHeight + spacing : 0)
+                             + (implicitFooterHeight > 0 ? implicitFooterHeight + spacing : 0))
+
+    padding: 6
+    horizontalPadding: 12
+
+    standardButtons: T.Dialog.Open | T.Dialog.Cancel
+
+    FolderDialogImpl.folderDialogListView: folderDialogListView
+    FolderDialogImpl.breadcrumbBar: breadcrumbBar
+
+    background: Rectangle {
+        implicitWidth: 600
+        implicitHeight: 400
+        color: control.palette.window
+        border.color: control.palette.mid
+        radius: 2
+
+        Rectangle {
+            z: -1
+            x: 1
+            y: 1
+            width: parent.width
+            height: parent.height
+            color: control.palette.shadow
+            opacity: 0.2
+            radius: 2
+        }
+    }
+
+    header: ColumnLayout {
+        spacing: 0
+
+        Label {
+            objectName: "dialogTitleBarLabel"
+            text: control.title
+            horizontalAlignment: Label.AlignHCenter
+            elide: Label.ElideRight
+            font.bold: true
+            padding: 6
+
+            Layout.fillWidth: true
+            Layout.leftMargin: 12
+            Layout.rightMargin: 12
+            Layout.topMargin: control.title.length > 0 ? 0 : 12
+            Layout.preferredHeight: control.title.length > 0 ? implicitHeight : 0
+        }
+
+        DialogsImpl.FolderBreadcrumbBar {
+            id: breadcrumbBar
+            dialog: control
+
+            Layout.fillWidth: true
+            Layout.leftMargin: 12
+            Layout.rightMargin: 12
+
+            KeyNavigation.tab: folderDialogListView
+        }
+    }
+
+    contentItem: Frame {
+        padding: 0
+        verticalPadding: 1
+
+        ListView {
+            id: folderDialogListView
+            objectName: "fileDialogListView"
+            anchors.fill: parent
+            clip: true
+            focus: true
+            boundsBehavior: Flickable.StopAtBounds
+
+            ScrollBar.vertical: ScrollBar {}
+
+            model: FolderListModel {
+                folder: control.currentFolder
+                showFiles: false
+                sortCaseSensitive: false
+            }
+            delegate: DialogsImpl.FolderDialogDelegate {
+                objectName: "folderDialogDelegate" + index
+                x: 1
+                width: ListView.view.width - 2
+                highlighted: ListView.isCurrentItem
+                dialog: control
+
+                KeyNavigation.backtab: breadcrumbBar
+                KeyNavigation.tab: control.footer
+            }
+        }
+    }
+
+    footer: DialogButtonBox {
+        id: buttonBox
+        standardButtons: control.standardButtons
+        spacing: 6
+        leftPadding: 0
+        rightPadding: 12
+        topPadding: 0
+        bottomPadding: 12
+        background: null
+    }
+
+    T.Overlay.modal: Rectangle {
+        color: Fusion.topShadow
+    }
+
+    T.Overlay.modeless: Rectangle {
+        color: Fusion.topShadow
+    }
+}