iOS Style: Add CheckDelegate control

Change-Id: I1d5b76b9c420302c1551622635842921ca047ae8
Reviewed-by: Mitch Curtis <mitch.curtis@qt.io>

2 files changed, 112 insertions, 0 deletions

diff --git a/src/quickcontrols2/ios/CMakeLists.txt b/src/quickcontrols2/ios/CMakeLists.txt
index be0928eab8..abcd1652fc 100644
--- a/src/quickcontrols2/ios/CMakeLists.txt
+++ b/src/quickcontrols2/ios/CMakeLists.txt
@@ -19,6 +19,7 @@ set(qml_files
     "ItemDelegate.qml"
     "SwitchDelegate.qml"
     "RadioDelegate.qml"
+    "CheckDelegate.qml"
 )
 set_source_files_properties(Slider.qml PROPERTIES
     QT_QML_SOURCE_VERSIONS "2.2;6.0"
diff --git a/src/quickcontrols2/ios/CheckDelegate.qml b/src/quickcontrols2/ios/CheckDelegate.qml
new file mode 100644
index 0000000000..6481af277d
--- /dev/null
+++ b/src/quickcontrols2/ios/CheckDelegate.qml
@@ -0,0 +1,111 @@
+/****************************************************************************
+**
+** Copyright (C) 2022 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the Qt Quick Controls 2 module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl-3.0.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or (at your option) the GNU General
+** Public license version 3 or any later version approved by the KDE Free
+** Qt Foundation. The licenses are as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL2 and LICENSE.GPL3
+** included in the packaging of this file. Please review the following
+** information to ensure the GNU General Public License requirements will
+** be met: https://www.gnu.org/licenses/gpl-2.0.html and
+** https://www.gnu.org/licenses/gpl-3.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick
+import QtQuick.Templates as T
+import QtQuick.Controls.iOS
+import QtQuick.Controls.impl
+
+T.CheckDelegate {
+    id: control
+    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
+                            implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
+                             implicitContentHeight + topPadding + bottomPadding,
+                             implicitIndicatorHeight + topPadding + bottomPadding)
+    padding: 7
+    leftPadding: 16
+    rightPadding: 16
+    spacing: 14
+
+    icon.width: 29
+    icon.height: 29
+    icon.color: control.enabled ? control.palette.text : control.palette.mid
+
+    indicator: Image {
+        x: control.mirrored ? control.leftPadding : control.width - width - control.rightPadding
+        y: control.topPadding + (control.availableHeight - height) / 2
+        opacity: control.enabled ? 1 : 0.5
+
+        source: control.IOS.url + (control.checkState === Qt.Unchecked ?  "radiobutton-indicator" : "checkbox-indicator")
+        ImageSelector on source {
+            states: [
+                {"checked": control.checkState === Qt.Checked},
+                {"partially-checked": control.checkState === Qt.PartiallyChecked},
+                {"light": control.IOS.theme === IOS.Light},
+                {"dark": control.IOS.theme === IOS.Dark}
+            ]
+        }
+    }
+
+    contentItem: IconLabel {
+        leftPadding: control.mirrored ? control.indicator.width + control.spacing : 0
+        rightPadding: !control.mirrored ? control.indicator.width + control.spacing : 0
+
+        spacing: control.spacing
+        mirrored: control.mirrored
+        display: control.display
+        alignment: control.display === IconLabel.IconOnly || control.display === IconLabel.TextUnderIcon ? Qt.AlignCenter : Qt.AlignLeft
+
+        icon: control.icon
+        text: control.text
+        font: control.font
+        color: control.enabled ? control.palette.text : control.palette.mid
+    }
+
+    background: Rectangle {
+        implicitHeight: 44
+        color: control.IOS.theme === IOS.Dark ? control.palette.dark : control.palette.base
+        NinePatchImage {
+            property real offset: control.icon.source.toString() !== "" ? control.icon.width + control.spacing : 0
+            x: control.down ? 0 : control.leftPadding + offset
+            y: control.down ? -1 : 0
+            height: control.height + (control.down ? 1 : 0)
+            width: control.down ? control.width : control.availableWidth + control.rightPadding - offset
+            source: control.IOS.url + "itemdelegate-background"
+            NinePatchImageSelector on source {
+                states: [
+                    {"light": control.IOS.theme === IOS.Light},
+                    {"dark": control.IOS.theme === IOS.Dark},
+                    {"pressed": control.down}
+                ]
+            }
+        }
+    }
+}