Add TableModel

This is a QML type that can be used as a model for the new TableView.

The model data is set by assigning a JavaScript array to the rows property
(or by calling appendRow()). After data has been assigned for the first time,
the available columns and roles are fixed for the lifetime of the model,
as opposed to ListModel where the dynamicRoles property could be used.
This is done intentionally to simplify the code.

The API is designed to be familiar to users of ListModel:
- To add new rows, use appendRow() and insertRow().
- To modify existing rows, use setRow(), moveRow(), removeRow(), and clear().

[ChangeLog][Qt Labs QML Models] Added the TableModel QML type, a
JavaScript-based model for the new TableView.

Fixes: QTBUG-70334
Change-Id: I55387a08b122227c5624f78af3d450b7695d974a
Reviewed-by: Shawn Rutledge <shawn.rutledge@qt.io>

4 files changed, 460 insertions, 0 deletions

diff --git a/tests/manual/tableview/tablemodel/RowForm.qml b/tests/manual/tableview/tablemodel/RowForm.qml
new file mode 100644
index 0000000000..428682008a
--- /dev/null
+++ b/tests/manual/tableview/tablemodel/RowForm.qml
@@ -0,0 +1,114 @@
+/****************************************************************************
+**
+** Copyright (C) 2018 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the QtQuick module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl-3.0.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or (at your option) the GNU General
+** Public license version 3 or any later version approved by the KDE Free
+** Qt Foundation. The licenses are as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL2 and LICENSE.GPL3
+** included in the packaging of this file. Please review the following
+** information to ensure the GNU General Public License requirements will
+** be met: https://www.gnu.org/licenses/gpl-2.0.html and
+** https://www.gnu.org/licenses/gpl-3.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.12
+import QtQuick.Controls 2.3
+import QtQuick.Layouts 1.11
+
+ScrollView {
+    clip: true
+
+    function inputAsRow() {
+        return [
+            { checkable: checkableCheckBox.checked, checked: checkedCheckBox.checked },
+            { amount: amountSpinBox.value },
+            { fruitType: fruitTypeTextField.text },
+            { fruitName: fruitNameTextField.text },
+            { fruitPrice: parseFloat(fruitPriceTextField.text) },
+        ]
+    }
+
+    default property alias content: gridLayout.children
+
+    GridLayout {
+        id: gridLayout
+        columns: 2
+
+        RowLayout {
+            Layout.columnSpan: 2
+
+            Label {
+                text: "checkable"
+            }
+            CheckBox {
+                id: checkableCheckBox
+                checked: true
+            }
+
+            Label {
+                text: "checked"
+            }
+            CheckBox {
+                id: checkedCheckBox
+            }
+        }
+
+        Label {
+            text: "amount"
+        }
+        SpinBox {
+            id: amountSpinBox
+            value: 1
+        }
+
+        Label {
+            text: "fruitType"
+        }
+        TextField {
+            id: fruitTypeTextField
+            text: "Pear"
+        }
+
+        Label {
+            text: "fruitName"
+        }
+        TextField {
+            id: fruitNameTextField
+            text: "Williams"
+        }
+
+        Label {
+            text: "fruitPrice"
+        }
+        TextField {
+            id: fruitPriceTextField
+            text: "1.50"
+        }
+    }
+}
diff --git a/tests/manual/tableview/tablemodel/main.cpp b/tests/manual/tableview/tablemodel/main.cpp
new file mode 100644
index 0000000000..2a3b90d392
--- /dev/null
+++ b/tests/manual/tableview/tablemodel/main.cpp
@@ -0,0 +1,52 @@
+/****************************************************************************
+**
+** Copyright (C) 2018 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the QtQuick module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl-3.0.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or (at your option) the GNU General
+** Public license version 3 or any later version approved by the KDE Free
+** Qt Foundation. The licenses are as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL2 and LICENSE.GPL3
+** included in the packaging of this file. Please review the following
+** information to ensure the GNU General Public License requirements will
+** be met: https://www.gnu.org/licenses/gpl-2.0.html and
+** https://www.gnu.org/licenses/gpl-3.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+#include <QGuiApplication>
+#include <QQmlApplicationEngine>
+
+int main(int argc, char *argv[])
+{
+    QCoreApplication::setAttribute(Qt::AA_EnableHighDpiScaling);
+    QGuiApplication app(argc, argv);
+
+    QQmlApplicationEngine engine;
+    engine.load(QUrl(QStringLiteral("qrc:/main.qml")));
+
+    return app.exec();
+}
diff --git a/tests/manual/tableview/tablemodel/main.qml b/tests/manual/tableview/tablemodel/main.qml
new file mode 100644
index 0000000000..f50fbf8781
--- /dev/null
+++ b/tests/manual/tableview/tablemodel/main.qml
@@ -0,0 +1,284 @@
+/****************************************************************************
+**
+** Copyright (C) 2018 The Qt Company Ltd.
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the QtQuick module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:LGPL$
+** Commercial License Usage
+** Licensees holding valid commercial Qt licenses may use this file in
+** accordance with the commercial license agreement provided with the
+** Software or, alternatively, in accordance with the terms contained in
+** a written agreement between you and The Qt Company. For licensing terms
+** and conditions see https://www.qt.io/terms-conditions. For further
+** information use the contact form at https://www.qt.io/contact-us.
+**
+** GNU Lesser General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU Lesser
+** General Public License version 3 as published by the Free Software
+** Foundation and appearing in the file LICENSE.LGPL3 included in the
+** packaging of this file. Please review the following information to
+** ensure the GNU Lesser General Public License version 3 requirements
+** will be met: https://www.gnu.org/licenses/lgpl-3.0.html.
+**
+** GNU General Public License Usage
+** Alternatively, this file may be used under the terms of the GNU
+** General Public License version 2.0 or (at your option) the GNU General
+** Public license version 3 or any later version approved by the KDE Free
+** Qt Foundation. The licenses are as published by the Free Software
+** Foundation and appearing in the file LICENSE.GPL2 and LICENSE.GPL3
+** included in the packaging of this file. Please review the following
+** information to ensure the GNU General Public License requirements will
+** be met: https://www.gnu.org/licenses/gpl-2.0.html and
+** https://www.gnu.org/licenses/gpl-3.0.html.
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.12
+import QtQuick.Controls 2.5
+import QtQuick.Layouts 1.12
+import QtQuick.Window 2.12
+import Qt.labs.qmlmodels 1.0
+
+ApplicationWindow {
+    id: window
+    width: 800
+    height: 800
+    visible: true
+
+    ColumnLayout {
+        anchors.fill: parent
+
+        TableView {
+            id: tableView
+            boundsBehavior: Flickable.StopAtBounds
+
+            ScrollBar.horizontal: ScrollBar {}
+            ScrollBar.vertical: ScrollBar {}
+
+            Layout.minimumHeight: window.height / 2
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+
+            model: TableModel {
+                // One row = one type of fruit that can be ordered
+                rows: [
+                    [
+                        // Each object (line) is one cell/column,
+                        // and each property in that object is a role.
+                        { checked: false, checkable: true },
+                        { amount: 1 },
+                        { fruitType: "Apple" },
+                        { fruitName: "Granny Smith" },
+                        { fruitPrice: 1.50 }
+                    ],
+                    [
+                        { checked: true, checkable: true },
+                        { amount: 4 },
+                        { fruitType: "Orange" },
+                        { fruitName: "Navel" },
+                        { fruitPrice: 2.50 }
+                    ],
+                    [
+                        { checked: false, checkable: true },
+                        { amount: 1 },
+                        { fruitType: "Banana" },
+                        { fruitName: "Cavendish" },
+                        { fruitPrice: 3.50 }
+                    ]
+                ]
+            }
+
+            delegate: DelegateChooser {
+                DelegateChoice {
+                    column: 0
+                    delegate: CheckBox {
+                        objectName: "tableViewCheckBoxDelegate"
+                        checked: model.checked
+                        onToggled: model.checked = checked
+                    }
+                }
+                DelegateChoice {
+                    column: 1
+                    delegate: SpinBox {
+                        objectName: "tableViewSpinBoxDelegate"
+                        value: model.amount
+                        onValueModified: model.amount = value
+                    }
+                }
+                DelegateChoice {
+                    delegate: TextField {
+                        objectName: "tableViewTextFieldDelegate"
+                        text: model.display
+                        selectByMouse: true
+                        implicitWidth: 140
+                        onAccepted: model.display = text
+                    }
+                }
+            }
+        }
+
+        TabBar {
+            id: operationTabBar
+
+            Layout.fillWidth: true
+            Layout.preferredHeight: 40
+
+            TabButton {
+                text: "Append"
+            }
+            TabButton {
+                text: "Clear"
+            }
+            TabButton {
+                text: "Insert"
+            }
+            TabButton {
+                text: "Move"
+            }
+            TabButton {
+                text: "Remove"
+            }
+            TabButton {
+                text: "Set"
+            }
+        }
+
+        StackLayout {
+            currentIndex: operationTabBar.currentIndex
+
+            ColumnLayout {
+                RowForm {
+                    id: appendRowForm
+
+                    Layout.fillHeight: true
+                }
+
+                Button {
+                    text: "Append"
+
+                    Layout.alignment: Qt.AlignRight
+
+                    onClicked: tableView.model.append(appendRowForm.inputAsRow())
+                }
+            }
+            ColumnLayout {
+                Button {
+                    text: "Clear"
+                    enabled: tableView.rows > 0
+
+                    onClicked: tableView.model.clear()
+                }
+            }
+            ColumnLayout {
+                RowForm {
+                    id: insertRowForm
+
+                    Layout.fillHeight: true
+
+                    Label {
+                        text: "Insert index"
+                    }
+                    SpinBox {
+                        id: insertIndexSpinBox
+                        from: 0
+                        to: tableView.rows
+                    }
+                }
+
+                Button {
+                    text: "Insert"
+
+                    Layout.alignment: Qt.AlignRight
+
+                    onClicked: tableView.model.insert(insertIndexSpinBox.value, insertRowForm.inputAsRow())
+                }
+            }
+            GridLayout {
+                columns: 2
+
+                Label {
+                    text: "Move from index"
+                }
+                SpinBox {
+                    id: moveFromIndexSpinBox
+                    from: 0
+                    to: tableView.rows > 0 ? tableView.rows - 1 : 0
+                }
+
+                Label {
+                    text: "Move to index"
+                }
+                SpinBox {
+                    id: moveToIndexSpinBox
+                    from: 0
+                    to: tableView.rows > 0 ? tableView.rows - 1 : 0
+                }
+
+                Label {
+                    text: "Rows to move"
+                }
+                SpinBox {
+                    id: rowsToMoveSpinBox
+                    from: 1
+                    to: tableView.rows
+                }
+
+                Button {
+                    text: "Move"
+                    enabled: tableView.rows > 0
+
+                    Layout.alignment: Qt.AlignRight
+                    Layout.columnSpan: 2
+
+                    onClicked: tableView.model.move(moveFromIndexSpinBox.value, moveToIndexSpinBox.value, rowsToMoveSpinBox.value)
+                }
+            }
+            GridLayout {
+                Label {
+                    text: "Remove index"
+                }
+                SpinBox {
+                    id: removeIndexSpinBox
+                    from: 0
+                    to: tableView.rows > 0 ? tableView.rows - 1 : 0
+                }
+
+                Button {
+                    text: "Remove"
+                    enabled: tableView.rows > 0
+
+                    Layout.alignment: Qt.AlignRight
+                    Layout.columnSpan: 2
+
+                    onClicked: tableView.model.remove(removeIndexSpinBox.value)
+                }
+            }
+            ColumnLayout {
+                RowForm {
+                    id: setRowForm
+
+                    Layout.fillHeight: true
+
+                    Label {
+                        text: "Set index"
+                    }
+                    SpinBox {
+                        id: setIndexSpinBox
+                        from: 0
+                        to: tableView.rows > 0 ? tableView.rows - 1 : 0
+                    }
+                }
+
+                Button {
+                    text: "Set"
+
+                    onClicked: tableView.model.set(setIndexSpinBox.value, setRowForm.inputAsRow());
+                }
+            }
+        }
+    }
+}
diff --git a/tests/manual/tableview/tablemodel/tablemodel.pro b/tests/manual/tableview/tablemodel/tablemodel.pro
new file mode 100644
index 0000000000..f6100276a1
--- /dev/null
+++ b/tests/manual/tableview/tablemodel/tablemodel.pro
@@ -0,0 +1,10 @@
+TEMPLATE = app
+TARGET = tableview_tablemodel
+QT += qml quick
+SOURCES += main.cpp
+RESOURCES += main.qml RowForm.qml
+
+# Default rules for deployment.
+qnx: target.path = /tmp/$${TARGET}/bin
+else: unix:!android: target.path = /opt/$${TARGET}/bin
+!isEmpty(target.path): INSTALLS += target