1 files changed, 117 insertions, 0 deletions
diff --git a/examples/qtquick/draganddrop/views/gridview.qml b/examples/qtquick/draganddrop/views/gridview.qml
new file mode 100644
index 0000000000..375f3d2824
--- /dev/null
+++ b/examples/qtquick/draganddrop/views/gridview.qml
@@ -0,0 +1,117 @@
+/****************************************************************************
+**
+** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
+** Contact: http://www.qt-project.org/
+**
+** This file is part of the examples of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** You may use this file under the terms of the BSD license as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
+**     the names of its contributors may be used to endorse or promote
+**     products derived from this software without specific prior written
+**     permission.
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.0
+
+GridView {
+    id: root
+    width: 360; height: 360
+    cellWidth: 90; cellHeight: 90
+
+    model: VisualDataModel {
+        id: visualModel
+        model: ListModel {
+            id: colorModel
+            ListElement { color: "blue" }
+            ListElement { color: "green" }
+            ListElement { color: "red" }
+            ListElement { color: "yellow" }
+            ListElement { color: "orange" }
+            ListElement { color: "purple" }
+            ListElement { color: "cyan" }
+            ListElement { color: "magenta" }
+            ListElement { color: "chartreuse" }
+            ListElement { color: "aquamarine" }
+            ListElement { color: "indigo" }
+            ListElement { color: "black" }
+            ListElement { color: "chartreuse" }
+            ListElement { color: "violet" }
+            ListElement { color: "grey" }
+            ListElement { color: "springgreen" }
+        }
+
+        delegate: MouseArea {
+            id: delegateRoot
+
+            property int visualIndex: VisualDataModel.itemsIndex
+
+            width: 90; height: 90
+            drag.target: icon
+
+            Rectangle {
+                id: icon
+                width: 80; height: 80
+                anchors {
+                    horizontalCenter: parent.horizontalCenter;
+                    verticalCenter: parent.verticalCenter
+                }
+                color: model.color
+                radius: 3
+
+                Drag.active: delegateRoot.pressed
+                Drag.source: delegateRoot
+                Drag.hotSpot.x: 40
+                Drag.hotSpot.y: 40
+
+                states: [
+                    State {
+                        when: icon.Drag.active
+                        ParentChange {
+                            target: icon
+                            parent: root
+                        }
+
+                        AnchorChanges {
+                            target: icon;
+                            anchors.horizontalCenter: undefined;
+                            anchors.verticalCenter: undefined
+                        }
+                    }
+                ]
+            }
+
+            DropArea {
+                anchors { fill: parent; margins: 15 }
+
+                onEntered: visualModel.items.move(drag.source.visualIndex, delegateRoot.visualIndex)
+            }
+        }
+    }
+}