1 files changed, 37 insertions, 0 deletions
diff --git a/examples/quick/scenegraph/rendernode/rendernode.pro b/examples/quick/scenegraph/rendernode/rendernode.pro
new file mode 100644
index 0000000000..d7ae715a7d
--- /dev/null
+++ b/examples/quick/scenegraph/rendernode/rendernode.pro
@@ -0,0 +1,37 @@
+QT += qml quick
+
+HEADERS += customrenderitem.h \
+           openglrenderer.h
+
+SOURCES += customrenderitem.cpp \
+           openglrenderer.cpp \
+           main.cpp
+
+RESOURCES += rendernode.qrc
+
+target.path = $$[QT_INSTALL_EXAMPLES]/quick/scenegraph/rendernode
+INSTALLS += target
+
+OTHER_FILES += \
+    main.qml \
+    shader.hlsl
+
+config_d3d12 {
+    DEFINES += HAS_D3D12
+    HEADERS += d3d12renderer.h
+    SOURCES += d3d12renderer.cpp
+    LIBS += -ld3d12
+
+    VSPS = shader.hlsl
+    vshader.input = VSPS
+    vshader.header = vs_shader.hlslh
+    vshader.entry = VS_Simple
+    vshader.type = vs_5_0
+    pshader.input = VSPS
+    pshader.header = ps_shader.hlslh
+    pshader.entry = PS_Simple
+    pshader.type = ps_5_0
+
+    HLSL_SHADERS = vshader pshader
+    load(hlsl_bytecode_header)
+}