1 files changed, 114 insertions, 0 deletions
diff --git a/src/quick/doc/snippets/qml/opacitymask.qml b/src/quick/doc/snippets/qml/opacitymask.qml
new file mode 100644
index 0000000000..e458f810ea
--- /dev/null
+++ b/src/quick/doc/snippets/qml/opacitymask.qml
@@ -0,0 +1,114 @@
+/****************************************************************************
+**
+** Copyright (C) 2014 Gunnar Sletta <gunnar@sletta.org>
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the documentation of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** You may use this file under the terms of the BSD license as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of Digia Plc and its Subsidiary(-ies) nor the names
+**     of its contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+import QtQuick 2.0
+
+Item {
+    id: root
+    width: 480
+    height: 320
+
+    // The checkers background
+    ShaderEffect {
+        id: tileBackground
+        anchors.fill: parent
+
+        property real tileSize: 20
+        property color color1: Qt.hsla(0, 0, 0.1);
+        property color color2: Qt.hsla(0, 0, 0.2);
+
+        property size pixelSize: Qt.size(width / tileSize, height / tileSize);
+
+        fragmentShader:
+            "
+            uniform lowp vec4 color1;
+            uniform lowp vec4 color2;
+            uniform highp vec2 pixelSize;
+            varying highp vec2 qt_TexCoord0;
+            void main() {
+                highp vec2 tc = sign(sin(3.14152 * qt_TexCoord0 * pixelSize));
+                if (tc.x != tc.y)
+                    gl_FragColor = color1;
+                else
+                    gl_FragColor = color2;
+            }
+            "
+    }
+
+//! [1]
+    Rectangle {
+        id: gradientRect;
+        width: 10
+        height: 10
+        gradient: Gradient {
+            GradientStop { position: 0; color: "white" }
+            GradientStop { position: 1; color: "steelblue" }
+        }
+        visible: false; // should not be visible on screen.
+        layer.enabled: true;
+        layer.smooth: true
+    }
+
+    Text {
+        id: textItem
+        font.pixelSize: 48
+        text: "Gradient Text"
+        anchors.centerIn: parent
+        layer.enabled: true
+        // This item should be used as the 'mask'
+        layer.samplerName: "maskSource"
+        layer.effect: ShaderEffect {
+            property var colorSource: gradientRect;
+            fragmentShader: "
+                uniform lowp sampler2D colorSource;
+                uniform lowp sampler2D maskSource;
+                uniform lowp float qt_Opacity;
+                varying highp vec2 qt_TexCoord0;
+                void main() {
+                    gl_FragColor =
+                        texture2D(colorSource, qt_TexCoord0)
+                        * texture2D(maskSource, qt_TexCoord0).a
+                        * qt_Opacity;
+                }
+            "
+        }
+    }
+//! [1]
+}