1 files changed, 0 insertions, 56 deletions
diff --git a/tools/tools.pro b/tools/tools.pro
deleted file mode 100644
index 21b23f20fa..0000000000
--- a/tools/tools.pro
+++ /dev/null
@@ -1,56 +0,0 @@
-TEMPLATE = subdirs
-QT_FOR_CONFIG += qml-private
-
-qtConfig(qml-devtools) {
-    SUBDIRS += \
-        qmllint \
-        qmlimportscanner \
-        qmlformat
-
-    qtConfig(xmlstreamwriter): SUBDIRS += qmlcachegen
-}
-
-qtConfig(thread):!android:!wasm:!rtems {
-    SUBDIRS += qml
-
-    qtConfig(qml-profiler): SUBDIRS += qmlprofiler
-    qtConfig(qml-preview): SUBDIRS += qmlpreview
-
-    qtHaveModule(quick) {
-        !contains(CONFIG, static) {
-            SUBDIRS += \
-                qmlscene \
-                qmltime
-
-            qtConfig(regularexpression):qtConfig(process) {
-                SUBDIRS += \
-                    qmlplugindump
-            }
-        }
-        qtHaveModule(widgets) {
-            QT_FOR_CONFIG += widgets
-            qtConfig(dialogbuttonbox) {
-                SUBDIRS += \
-                    qmleasing
-            }
-        }
-    }
-    qtHaveModule(qmltest): SUBDIRS += qmltestrunner
-    qtConfig(private_tests): SUBDIRS += qmljs
-}
-
-qtConfig(qml-devtools) {
-    qml.depends = qmlimportscanner
-    qmleasing.depends = qmlimportscanner
-}
-
-# qmlimportscanner & qmlcachegen are build tools.
-# qmlscene is needed by the autotests.
-# qmltestrunner may be useful for manual testing.
-# qmlplugindump cannot be a build tool, because it loads target plugins.
-# The other apps are mostly "desktop" tools and are thus excluded.
-qtNomakeTools( \
-    qmlprofiler \
-    qmlplugindump \
-    qmleasing \
-)