/****************************************************************************
**
** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
** All rights reserved.
** Contact: Nokia Corporation (qt-info@nokia.com)
**
** This file is part of the examples of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:BSD$
** You may use this file under the terms of the BSD license as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
**     the names of its contributors may be used to endorse or promote
**     products derived from this software without specific prior written
**     permission.
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick 2.0
import Qt.labs.inputcontext 1.0 as InputContext

Item {
    width: 360
    height: 240

    function filterKeyPress(key, text)
    {
        switch (key) {
        case Qt.Key_Enter:
        case Qt.Key_Return:
        case Qt.Key_Space:
        case Qt.Key_Tab:
            if (InputContext.preeditText != "")
                InputContext.commit();
            break;
        case Qt.Key_Backspace:
            if (InputContext.preeditText != "") {
                InputContext.preeditText = InputContext.preeditText.substr(0, InputContext.preeditText.length - 1);
                return true;
            }
            break;
        default:
            if (text != "") {
                InputContext.preeditText += text
                return true;
            } else if (InputContext.preeditText != "") {
                InputContext.commit();
            }
            break;
        }
        return false;
    }

    Rectangle {
        anchors.left: parent.left; anchors.top: parent.top; anchors.right: parent.right;
        anchors.bottom: keyboard.top
        anchors.margins: 2

        border.width: 1
        radius: 2

        TextEdit {
            id: textEdit

            wrapMode: TextEdit.WordWrap

            anchors.fill: parent
            anchors.margins: 2
        }

        MouseArea {
            anchors.fill: textEdit

            onPressed: {
                mouse.accepted = false
                var position = textEdit.positionAt(mouse.x, mouse.y);
                if (position != textEdit.cursorPosition) {
                    InputContext.commit()
                    textEdit.cursorPosition = textEdit.positionAt(mouse.x, mouse.y)
                    textEdit.selectWord()
                    var word = textEdit.selectedText
                    if (word != "") {
                        InputContext.commit("");
                        InputContext.preeditText = word;
                    }
                }
            }
        }
    }

    WordSuggestions {}

    Keyboard {
        id: keyboard
        anchors.horizontalCenter: parent.horizontalCenter

        y: parent.height

        states: [
            State {
                name: "visible"
                PropertyChanges { target: keyboard; y: parent.height - height }
                when: InputContext.softwareInputPanelVisible
            },
            State {
                name: "hidden"
                PropertyChanges { target: keyboard; y: parent.height }
                when: !InputContext.softwareInputPanelVisible
            }
        ]
        transitions: Transition {
            NumberAnimation { properties: "y"; easing.type: Easing.InOutQuad; duration: 100 }
        }
    }
}