examples/quick/mousearea/mousearea-wheel-example.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

// Copyright (C) 2021 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause

import QtQuick

Rectangle {
    height: 700
    width: 485
    color: "#333333"

    Column {
        anchors.centerIn: parent
        spacing: 2

        Repeater {
            model: ["#9ACD32", "#EEEEEE", "#FFD700", "#87CEEB"]

            Rectangle {
                required property color modelData

                property real scaleFactor: 1

                height: 40 * scaleFactor
                width: 60 * scaleFactor
                color: modelData
                anchors.horizontalCenter: parent.horizontalCenter

                MouseArea {
                    anchors.fill: parent
                    onWheel: {
                        if (wheel.modifiers & Qt.ControlModifier) {
                            parent.scaleFactor += 0.2 * wheel.angleDelta.y / 120;
                            if (parent.scaleFactor < 0)
                                parent.scaleFactor = 0;
                        }
                    }
                }
            }
        }
    }

    Text {
        anchors.bottom: parent.bottom
        anchors.horizontalCenter: parent.horizontalCenter
        color: "#FFD700"
        text: "Rotate the mouse wheel pressing <Control> to resize the squares."
    }
}