summaryrefslogtreecommitdiffstats
path: root/examples/quick/scenegraph/rendernode/rendernode.pro
blob: 851d5927bd58499d92088fb7bde818e2fc1a75ab (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
QT += qml quick

HEADERS += customrenderitem.h \
           openglrenderer.h \
           softwarerenderer.h

SOURCES += customrenderitem.cpp \
           openglrenderer.cpp \
           softwarerenderer.cpp \
           main.cpp

RESOURCES += rendernode.qrc

target.path = $$[QT_INSTALL_EXAMPLES]/quick/scenegraph/rendernode
INSTALLS += target

OTHER_FILES += \
    main.qml \
    shader.hlsl

config_d3d12 {
    DEFINES += HAS_D3D12
    HEADERS += d3d12renderer.h
    SOURCES += d3d12renderer.cpp
    LIBS += -ld3d12

    VSPS = shader.hlsl
    vshader.input = VSPS
    vshader.header = vs_shader.hlslh
    vshader.entry = VS_Simple
    vshader.type = vs_5_0
    pshader.input = VSPS
    pshader.header = ps_shader.hlslh
    pshader.entry = PS_Simple
    pshader.type = ps_5_0

    HLSL_SHADERS = vshader pshader
    load(hlsl_bytecode_header)
}