src/plugins/qmltooling/qmltooling.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

TEMPLATE = subdirs
QT_FOR_CONFIG += qml-private

# Utilities
SUBDIRS += \
    packetprotocol

# Connectors
SUBDIRS += \
    qmldbg_native \
    qmldbg_server

qmldbg_native.depends = packetprotocol
qmldbg_server.depends = packetprotocol

qtConfig(qml-network) {
    SUBDIRS += \
        qmldbg_local \
        qmldbg_tcp
}

qtConfig(qml-interpreter) {
    # Services
    SUBDIRS += \
        qmldbg_debugger \
        qmldbg_profiler \
        qmldbg_messages \
        qmldbg_nativedebugger

    qmldbg_debugger.depends = packetprotocol
    qmldbg_profiler.depends = packetprotocol
    qmldbg_messages.depends = packetprotocol
    qmldbg_nativedebugger.depends = packetprotocol
}

qtHaveModule(quick) {
    SUBDIRS += \
        qmldbg_inspector \
        qmldbg_quickprofiler
    qmldbg_inspector.depends = packetprotocol
    qmldbg_quickprofiler.depends = packetprotocol
}